Datenstruktur aus Win in Notes DB übernehmen

Redest du jetzt von MailFoldern oder von WebSeiten oder von was ?

Benutz doch bitte die Suchfunktion, das hatten wir hier schon mehrfach

Such doch einmal nach DNFS und Nachfolgesystemen. Vielleicht ist es genau das, was du suchst. Das ist genial für Notebookler, die sich ein Abteilungsverzeichnis lokal aktuell halten wollen/sololen/müssen.

Ein Abteilungsverzeichnis gehört IMO nicht in eine Notes-DB! Da bringt Windows eigene Mechanismen mit (Stichwort: "Aktenkoffer" oder "Offlinedateien")

Wenn du Laufwerkmappings je nach Anbindung eines Notebooks (lokal, Netz) unterschiedlich zuweist, wirst du mit Aktenkoffern schnell an einem Punkt landen, der die Qualität deiner Sicherungsmechanismen zu Tage fördert - das ist Müll.

Lotus hat in Version 5 DNFS eingeführt, aber in Version 6 nicht fortgesetzt. Man hatte angekündigt, DNFS durch WEBDAV abzulösen. Damit hätte man einen genialen "Fileserverersatz" mit Web-Fähigkeiten. Leider ist das WEBDAV damals aus dem Katalog der "Mitbringsel" von R6 gestrichen worden.

Ich wäre heute vorsichtig, auf einen 5er Server noch DNFS aufzusetzen, denn damit schließe ich ihn von einem Upgrade auf R6 aus. WEBDAV wird kommen, aber ich weiß nicht, ob es in R7 drin ist.

Wenn ja, dann kann das das Ziel für unseren Freund - und viele andere - sein.

Also andersherum habe ich das schon programmiert....

Angehängte Dateien einer kategorisierten Datenbank exportiert in einzelne Verzeichnisse...

Der Import sollte eigentlich auch nicht all zu schwer zu programmieren sein....

Vielleicht postest Du das Problem mal im Domino-Designer Forum....

Gruß

Norbert

Ich würde das mit Offline Dateien von Windows machen, funktioniert eigentlich absolut problemlos, solange nur ein Benutzer auf dem Verzeichnis arbeitet...

Die Diskussionen um das Für und Wider von Offline-Foldern helfen unserem Freund nicht weiter.

Ich habe aus meinen ersten LS-Programmierertagen eine Einleseroutine gefunden (es ist abscheulicher Spaghetticode - ich weiß es), die genau das tut, was unser Freund will. Hier ist das Programm:

(Declarations)
'Dim Begriff1 As String, Begriff2 As String, Begriff3 As String, Begriff4 As String, Begriff5 As String, Begriff6 As String
Dim Begriff (6) As String, Begriff1 (6) As String, Trenner (2) As String
Dim zaehlerBegriff As Integer, zaehlerBegriff1 As Integer, zaehlerTrenner As Integer, MaxzaehlerTrenner As Integer, LaengeAktTrenner As Integer
Dim dsn As String
Dim Verwerfen As Integer, txt1 As String, txt2 As String, txt3 As String
Dim Aufhoeren As Variant
Dim igesamt As Integer

Sub Initialize
On Error Goto ProcessError
' Dieses Programm dient dazu, Dokumentationen aus bestehenden Dateisystemen aufzubauen, indem man die bestehende Verzeichnisstruktur
' sowie den Dateinamen als kategorisierende Elemente heranzieht. Die zu importierenden Dateinamen müssen zeilenweise aufgeführt sein. Es dürfen
' auch Zeilen vorkommen, die keinen Dateinamen enthalten. Zeilen, die mit einem Simokolon beginnen (;) sowie Zeilen, die das Suchkriterium
' (Vorhandensein von ":\") nicht enthalten, werden überlesen. Vor dem Dateinamen selbst darf ruhig noch etwas anderes stehen.
' Am einfachsten wird eine Dateiliste der anzuhängenden Dateien generiert, indem man folgendes tut:
' 1. Man stellt sich im DOS-Fenster in das Verzeichnis, dessen Dateien und Unterverzeichnisse man einlesen möchte und setzt den Befehl ab
' attrib *.*/s > dateiliste1.txt
' 2. Man startet Word und stellt unter EXTRAS - OPTIONEN - ALLGEMEIN ein, daß man Konvertierungen bestätigen möchte
' 3. Mon öffnet die dateiliste1.txt als Text-Datei und wählt den Konverter DOS-Text
' 4. Man speichert diese Datei als Textdatei unter dateiliste2.txt als Textdatei ab. Jetzt sind die Umlaute in Datei- und Verzeichnisnamen richtiggestellt
' 5. Man editiert diesen Agenten und setzt den Dateinamen dateiliste2.txt in die zu öffnende Datei ein
' 6. Man setzt den Wert von VERWERFEN richtig (Verwerfen bezeichnet die für die Schlagwortbildung nicht zu berücksichtigenden
' Unterverzeichnisse, z.B. lautet der Dateiname C:\v1\v2\Thema\Sprache\Jahr\Vortrag\wichtig.ppt
' Dann lautet mit VERWERFEN=2 die von der Unterroutine ZERLEGE zurückgegebenen Werte
' Begriff(0) Thema
' Begriff(1) Sprache
' Begriff(2) Jahr
' Begriff(3) Vortrag
' Begriff(4) <leer>
' Begriff(5) <leer>
' Begriff1(0) wichtig
' Begriff1(1) ... Begriff1(5) <leer>
' dsn C:\v1\v2\Thema\Sprache\Jahr\Vortrag\wichtig.ppt
' 7. Jetzt muß man die Felder doc.theme, doc.division1, doc.division2 ... doc.division4 sowie doc.DocNr und doc.docdescription
' aus den Begriffen füllen
'
Dim session As New NotesSession
Dim db As NotesDatabase
Dim doc As NotesDocument
' Dim workspace As New NotesUIWorkspace
' Dim uidoc As NotesUIDocument
' Dim view As NotesView
Dim i As Integer, i1 As Integer, i2 As Integer
Dim text As String, fileNum As Integer
Dim rtitem As NotesRichTextItem
Dim object As NotesEmbeddedObject
Dim handle As Variant
' Set uidoc = workspace.CurrentDocument
Set db = session.CurrentDatabase
fileNum% = Freefile()
Open "c:\TEMP\TEST.TXT" For Input As fileNum%
Verwerfen=2
Trenner(0)="\"
Trenner(1)=".xls"
MaxZaehlerTrenner=1
' Open "c:\Präsentationen\attribtxtkonvtest.txt" For Input As fileNum%
igesamt=0
Do While Not Eof(fileNum%)
Line Input #1, text$
i1=Instr(1,text$,":\",1)
If i1>0 And Not Left(Text$,1)=";" Then
i2=Len(text$)
dsn=Mid(text$,i1-1,i2-i1+2)
igesamt=igesamt+1
Print Cstr(igesamt)&". File: "&dsn
' Test, ob Datei im Dateisystem vorhanden ist, die Error-Routine setzt den Wert TestVorhanden auf FALSE, wenn Datei sich nicht öffnen läßt
TestVorhanden=True
fileNum1% = Freefile()
Open dsn For Input As fileNum1%
Close fileNum1%
If TestVorhanden Then
Erase Begriff
Erase Begriff1
ZaehlerTrenner=0
LaengeAktTrenner=Len(Trenner(ZaehlerTrenner))
Call Zerlege (dsn, Verwerfen, Begriff, Begriff1)
Set doc = db.CreateDocument
doc.form="Doc"
doc.Erstellmaske="Doc"
doc.DispIcon = 1
doc.owner=session.effectiveUsername
doc.DocAuthor=session.CommonUsername
doc.PastAuthors=session.CommonUsername
doc.PastEditDates=Now
doc.TimesModified=1
doc.Type="Dokument"
doc.Theme="SV-FA-AE/A\Allgemein"
doc.docdescription=Begriff1(0)
doc.division1=Begriff(0)
doc.division2=Begriff(1)
doc.division3=Begriff(2)
doc.division4=Begriff(3)
Set rtitem = New NotesRichTextItem ( doc, "Body" )
Call rtItem.EmbedObject( EMBED_ATTACHMENT, "", dsn )
' Call rtItem.EmbedObject( EMBED_OBJECT, "", dsn,"Test" )
' Set object = rtItem.EmbedObject( EMBED_OBJECT, "PowerPoint.Show.8", dsn,"Test" )
' Set handle = object.Activate( False )
' If ( handle Is Nothing ) Then
' doc.Subject = "This object has no OLE automation interface"
' End If
Call doc.Save( True, True )
End If
End If
Loop
Messagebox Cstr(igesamt)+" Files eingelesen/read"
Close fileNum%
Exit Sub
ProcessError:
If Cstr(Err)="101" Then
TestVorhanden=False
Print "Datei nicht vorhanden: "&dsn
Beep
Resume Next
Else
Msgbox "Error (" & Cstr(Err) & ") -> " & Error$(Err),16,"Fehler bei DATEI EINLESEN"
Close fileNum%
Print "Datei geschlossen"
Exit Sub
End If
End Sub

Sub Zerlege (dsn, Verwerfen, Begriff, Begriff1)
Aufhoeren=False
txt1=dsn
i1=0
While i1<=Verwerfen And Not Aufhoeren
Call Teilen (txt1,txt2)
i1=i1+1
Wend
zaehlerBegriff=0
zaehlerBegriff1=0
While Not Aufhoeren
If zaehlerTrenner =0 Then
Begriff(zaehlerBegriff)=txt2
zaehlerBegriff=zaehlerBegriff+1
Else
Begriff1(zaehlerBegriff1)=txt2
zaehlerBegriff1=zaehlerBegriff1+1
End If
Call Teilen (txt1,txt2)
Wend
End Sub

Sub Teilen (txt1,txt2)
Dim L1 As Integer, Ltxt1 As Integer, txttest As String
If txt1=txt2 Or txt1="" Then
Aufhoeren=True
Exit Sub
End If
L1=Instr(txt1,Trenner(zaehlerTrenner))
Ltxt1=Len(txt1)
If L1>0 Then
txt1=Mid(txt1, L1+LaengeAktTrenner,Ltxt1-LaengeAktTrenner)
Ltxt1=Len(txt1)
L1=Instr(txt1,Trenner(zaehlerTrenner))
If L1>0 Then
txt2=Left(txt1,L1-1)
Else
zaehlerTrenner=zaehlerTrenner+1
LaengeAktTrenner=Len(Trenner(ZaehlerTrenner))
If zaehlerTrenner>MaxzaehlerTrenner Then Aufhoeren=True
L1=Instr(txt1,Trenner(zaehlerTrenner))
If L1>0 Then
txt2=Left(txt1,L1-1)
txttest=Mid(txt1, L1+LaengeAktTrenner,Ltxt1-LaengeAktTrenner)
L1=Instr(txttest,Trenner(zaehlerTrenner))
If L1=0 Then txt1=txt2
End If
End If
Else
' zaehlerTrenner=zaehlerTrenner+1
L1=Instr(txt1,Trenner(zaehlerTrenner))
If L1>0 Then
txt2=Left(txt1,L1-1)
txt1=Mid(txt1, L1+LaengeAktTrenner,Ltxt1-LaengeAktTrenner)
L1=Instr(txt1,Trenner(zaehlerTrenner))
If L1=0 Then txt1=txt2
End If
End If
End Sub

Probier es aus, ob es das bringt, was du möchtest.

Wenn ich mich recht erinnere, macht das Programm Fehler, wenn im Dateinamen mehr als ein Punkt vorkommt. Ich würde ohnehin die ZERLEGE und TEILE-Prozeduren heute völlig neu programmieren, damit man sie verstehen kann, aber im Debugger kann man sich das Ding ja einmal anschauen, was er aus einer Dateiliste macht.

Ich weiß noch, daß wir damals auf diese Weise gut 2000 Grafiken, die noch unter DOS Harvard Graphics erstellt gewesen waren, von einem Studenten in Powerpoint neu haben aufbauen lassen und so als statischen Fundus in einer Notes-DB aufbereitet haben.

Natürlich kann man auch mit Ordnern arbeiten, aber Ordner sind Dokumente - und wenn zwei Bearbeiter evtl. später in deiner DB die gleichen Ordnerstrukturen ändern, wird sich die Arbeit von mindestens einem Mitarbeiter anschließend nicht mehr in den Ordnern wiederfinden (Ordner produzieren beim Replizieren keine Replikationskonflikte - einer "gewinnt"). Deshalb habe ich damals eine pseudohierarchische Begriffs-Struktur in jedem Dokument eingeführt.

In den Ansichten baust du eine Kategorie mit
Begriff0 + @If(Begriff1="";"";"\\"+Begriff1 +@If(Begriff2="";"";"\\"+Begriff2 + @If(Begriff3="";"";"\\"+Begriff3 + @If(Begriff4="";"";"\\"+Begriff4))))

Da das Berechnen dieses Ausdrucks ein wenig Zeit kostet, kannst du das natürlich auch in jedem Dokument in einem berechneten Feld hinterlegen und dieses Feld als Kategorie anzeigen lassen.

Hi,

ich hatte da auch mal was gebaut, was basiernd aus einem Startverzeichnis, das komplette Filesystem durchmarschiert und pro File im Verzeichnis ein Notesdokument baut.

Das steht in den Declarations,

Dim dirs() As String
Dim count As Integer

und folgende Subs gibts:

Sub Initialize
&nbsp;&nbsp;
&nbsp;&nbsp;Redim dirs(0)
&nbsp;&nbsp;count = 0
&nbsp;&nbsp;act = 0
&nbsp;&nbsp;
&nbsp;&nbsp;dirs(0) = "d:\test"
&nbsp;&nbsp;Do
&nbsp;&nbsp;&nbsp;&nbsp;getDirs(dirs(act))
&nbsp;&nbsp;&nbsp;&nbsp;act = act + 1
&nbsp;&nbsp;Loop While act <= count
&nbsp;&nbsp;For i = 0 To count
&nbsp;&nbsp;&nbsp;&nbsp;import(dirs(i))
&nbsp;&nbsp;Next
&nbsp;&nbsp;
End Sub

Sub getDirs(pDir As String)
&nbsp;&nbsp;
&nbsp;&nbsp;Dim s As New notessession
&nbsp;&nbsp;Dim d As notesdocument
&nbsp;&nbsp;
&nbsp;&nbsp;Dim filedir As String
&nbsp;&nbsp;Dim attr As Integer
&nbsp;&nbsp;
&nbsp;&nbsp;filedir = Dir$(pDir & "\*.*", 16)
&nbsp;&nbsp;While filedir <> ""
&nbsp;&nbsp;&nbsp;&nbsp;If filedir <> "." And filedir <> ".." Then
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;attr = Getfileattr(pDir & "\" & filedir)
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;If attr = 16 Then
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;count = count + 1
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Redim Preserve dirs(count)
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;dirs(count) = pDir & "\" & filedir
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;End If
&nbsp;&nbsp;&nbsp;&nbsp;End If
&nbsp;&nbsp;&nbsp;&nbsp;filedir = Dir$
&nbsp;&nbsp;Wend
&nbsp;&nbsp;
End Sub

Sub import(pDir As String)
&nbsp;&nbsp;
&nbsp;&nbsp;Dim s As New NotesSession
&nbsp;&nbsp;Dim d As NotesDocument
&nbsp;&nbsp;Dim filename As String
&nbsp;&nbsp;
&nbsp;&nbsp;filename = Dir$(pDir & "\*.*")
&nbsp;&nbsp;
&nbsp;&nbsp;While filename <> ""
&nbsp;&nbsp;&nbsp;&nbsp;If filename <> "." And filename <> ".." Then
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Set d = s.CurrentDatabase.CreateDocument
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;d.form = "import"
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;d.path = pDir
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;d.file = filename
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Set rtitem = New NotesRichTextItem ( d, "Body" )
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Call rtItem.EmbedObject( EMBED_ATTACHMENT, "", pDir & "\" & filename)
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Call d.Save(True, True)&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;
&nbsp;&nbsp;&nbsp;&nbsp;End If
&nbsp;&nbsp;&nbsp;&nbsp;filename = Dir
&nbsp;&nbsp;Wend
&nbsp;&nbsp;
End Sub

cu

Jörg

Designer öffnen
Erstellen Agent
Gemeinsam ankreuzen
Namen geben (z.B. "Einlesen Dateien")
Manuell aus dem Menü AKTIONEN
Einmal ausführen
LOTUS SCRIPT auswählen
Cut&Paste vom Code
Dann kannst du den Code schon ordentlich lesen
Die entsprechenden Aktionen vorbereiten
Debugger einstellen
testweise laufen lassen (in leerer oder Test-Datenbank !!)

Lotus-Schulungsunterlagen raussuchen und Kurs Entwickler besuchen oder alles aus der Hilfe lernen.

Hi,

hier mal der neue Code inkl. Error-Handling:

Sub Initialize

On Error Goto error_handling

Redim dirs(0)
count = 0
act = 0

dirs(0) = "d:\StartDirectory"
Do
getDirs(dirs(act))
act = act + 1
Loop While act <= count
For i = 0 To count
import(dirs(i))
Next
ende:
Exit Sub

error_handling:
Messagebox "Initialize: ERR : " & Cstr(Err) & " - ERL : " & Cstr(Erl) & " - ERROR: " & Error
Resume ende
End Sub

Sub getDirs(pDir As String)

On Error Goto error_handling

Dim s As New notessession
Dim d As notesdocument

Dim filedir As String
Dim attr As Integer

filedir = Dir$(pDir & "\*.*", 16)
While filedir <> ""
If filedir <> "." And filedir <> ".." Then
attr = Getfileattr(pDir & "\" & filedir)
If attr = 16 Then
count = count + 1
Redim Preserve dirs(count)
dirs(count) = pDir & "\" & filedir
End If
End If
filedir = Dir$
Wend
ende:
Exit Sub

error_handling:
Messagebox "getDirs: ERR : " & Cstr(Err) & " - ERL : " & Cstr(Erl) & " - ERROR: " & Error & " - pDir: " & pDir
Resume ende
End Sub

Sub import(pDir As String)

On Error Goto error_handling

Dim s As New NotesSession
Dim d As NotesDocument
Dim filename As String

filename = Dir$(pDir & "\*.*")

While filename <> ""
If filename <> "." And filename <> ".." Then
Set d = s.CurrentDatabase.CreateDocument
d.form = "import"
d.path = pDir
d.file = filename
Set rtitem = New NotesRichTextItem ( d, "Body" )
Call rtItem.EmbedObject( EMBED_ATTACHMENT, "", pDir & "\" & filename)
Call d.Save(True, True)
End If
filename = Dir
Wend
ende:
Exit Sub

error_handling:
Messagebox "import: ERR : " & Cstr(Err) & " - ERL : " & Cstr(Erl) & " - ERROR: " & Error & " - pDir: " & pDir
Resume ende
End Sub

Dann sollte eigentlich recht schnell klar werden, wo das Problem liegen könnte.

@Dali:

Umlaute sollten kein Problem darstellen. Das habe ich getestet und es funktioniert.

Poste mal den Inhalt von der Meldung und wir schauen weiter.
cu

Jörg