Lotusscript kann eine Datenbank nicht öffnen

Wenn ich mich recht erinnere, geht das so nicht: ein schedulter Agent kann eine DB auf diese Weise nicht auf einem anderen Server öffnen. Das geht IIRC nur mit einem UI-Agenten. Und dann muss entweder der Signer, oder der Ausführer, die entsprechenden Rechte auf dem Remote Server haben ("Run Unrestricted LotusScript Agents" oder so hieß das).

Wenn es ein schedulter Agent ist, muss der Server, auf dem der Agent läuft, Manager in der ACL der Remote DB sein.

Das müsste gehen:

Dim s As New NotesSession
Dim db As NotesDatabase
Set db = s.GetDatabase( "server", "path/to/file")
Call db.Open("","")

Dass "db.Openbyreplicaid("","C1257111004084AS")" funktioniert, liegt einfach daran, dass es auf dem lokalen Server eine DB mit dieser ReplicaID hat und sie für den Signer oder ausführer des Agenten zugreifbar ist.

"db.Openbyreplicaid("irgendein-remote-server","C1257111004084AS")" würde vermutlich nicht funktionieren.

Das müsstest du mit dem Debugger eigentlich auch nachvollziehen können.

Zitat von RockWilder

Wenn ich mich recht erinnere, geht das so nicht: ein schedulter Agent kann eine DB auf diese Weise nicht auf einem anderen Server öffnen.

Doch, das geht. Der Server, auf dem der Agent läuft, muss auf dem Server, auf den der Agent zugreifen soll, lediglich in dessen Serverdokument unter Sicherheit > Serverzugriff bei den Vertrauenswürdigen Servern (Trusted Servers) aufgeführt sein.

Alle anderen Berechtigungen (ACL der Quell- und Ziel-DB, Ausführungsrechte für Agenten etc.) müssen natürlich außerdem noch passen.

HTH

Carsten

Dein Code ist noch etwas "wirr", so überschreibst du z.B. die Variable db bevor du sie überhaupt benutzt hast.

Den Servernamen brauchst du ebenfalls nicht solange alle Datenbanken und Agenten auf dem gleichen Server liegen und dort auch ausgeführt werden.

Ändere deinen Test-Code mal wie folgt, dann funktionierts auch.

Und, falls doch nicht, solltest du jetzt eine sprechende Fehlermeldung bekommen.

HTH

Carsten

%REM
    Function LesePersonen
%END REM
Function LesePersonen As String
    On Error GoTo ErrHandler
    
    Dim s As New NotesSession
    Dim dbUser As New NotesDatabase("", "")
    Dim dbOrga As New NotesDatabase("", "")

    LesePersonen="Datenbank(en) nicht geöffnet"
    
    Call dbUser.Open("","it\Benutzer.nsf")
    Call dbOrga.Open("","ebuero\OrgaKrKle.nsf")
    
    If dbUser.IsOpen And dbOrga.IsOpen Then
        LesePersonen="Datenbanken erfolgreich geöffnet"
    End If

ExitFunction:
    Exit Function
        
ErrHandler:
    Print |Error |+CStr(Err)+|: Code Erweiterungen -> LeitsystemXML Agent: LesePersonen - |+Error$
    Resume ExitFunction
End Function

Vorab: der von mir gepostete Code war exakt so lauffähig wie ich ihn gepostet habe.

Ich habe das getestet, nur die Dateinamen habe ich durch bei mir vorhandene DBs ersetzt.

Und natürlich hatte mein Agent im Initialize beim Testen noch den Aufruf "Print Lesepersonen" damit überhaupt etwas passiert.

Ich habe deinen Code jetzt so geändert, dass alle Infos sequentiell in den Rückgabewert wandern, nicht benötigte Variablen habe ich weggelassen.

Wenn also keine Fehler bei der Ausführung auftreten und den ErrorHandler triggern gibt es zwei mögliche Ausgaben (einmal mit NOT und einmal ohne):

Start > dbUser is NOT open > dbOrga is NOT open > End

Mein Agent funktioniert und gibt aus:

[15E4:0012-1BEC] { namgr:#2E62} 12.06.2024 15:46:04 Agent Manager: Agent printing: Start > dbUser is open > dbOrga is open > End

Hier der komplette Agent, mit dem ich getestet und obige Zeile produziert habe (nur die Dateinamen wurden geändert):

%REM
    Agent opentest
    Created 11.06.2024 by Carsten 
    Description: Comments for Agent
%END REM
Option Public
Option Declare

Sub Initialize
    Print Lesepersonen
End Sub

Function LesePersonen As String
    On Error GoTo ErrHandler
    LesePersonen="Start"
    
    Dim dbUser As New NotesDatabase("","")
    Dim dbOrga As New NotesDatabase("","")
    
    Call dbUser.Open("","it\Benutzer.nsf")
    If dbUser.IsOpen Then 
        LesePersonen=LesePersonen+" > dbUser is open"
    Else
        LesePersonen=LesePersonen+" > dbUser is NOT open"
    End if
    
    Call dbOrga.Open("","ebuero\OrgaKrKle.nsf")
    If dbOrga.IsOpen Then 
        LesePersonen=LesePersonen+" > dbOrga is open"
    Else
        LesePersonen=LesePersonen+" > dbOrga is NOT open"
    End If

ExitFunction:
    LesePersonen=LesePersonen+" > End"
    Exit Function
    
ErrHandler:
    Print |Error|+Str(Err)+|: Code Erweiterungen -> LeitsystemXML Agent: LesePersonen - |+Error$
    Resume ExitFunction
End Function

Ich rate mal, dass du den Agenten mit deinem Client startest.

Damit läuft der Agent auf deiner Workstation und nicht auf dem Server und sucht an der falschen Stelle nach den DBs.

Damit die DBs auch auf dem Server gesucht und verwendet werden, auf dem der Agent abgelegt ist, habe ich den Code angepasst.

HTH

Carsten

%REM
    Agent opentest
    Created 13.06.2024 by Carsten 
    Description: Comments for Agent
%END REM
Option Public
Option Declare

Sub Initialize
    Print Lesepersonen
End Sub

Function LesePersonen As String
    On Error GoTo ErrHandler
    LesePersonen="Start"

    Dim s As New NotesSession
    Dim myServer As String
    
    myServer = s.Currentdatabase.Server

    Dim dbUser As New NotesDatabase("","")
    Dim dbOrga As New NotesDatabase("","")
    
    Call dbUser.Open(myServer,"it\Benutzer.nsf")
    If dbUser.IsOpen Then 
        LesePersonen=LesePersonen+" > dbUser is open"
    Else
        LesePersonen=LesePersonen+" > dbUser is NOT open"
    End if
    
    Call dbOrga.Open(myServer,"ebuero\OrgaKrKle.nsf")
    If dbOrga.IsOpen Then 
        LesePersonen=LesePersonen+" > dbOrga is open"
    Else
        LesePersonen=LesePersonen+" > dbOrga is NOT open"
    End If

ExitFunction:
    LesePersonen=LesePersonen+" > End"
    Exit Function
    
ErrHandler:
    Print |Error|+Str(Err)+|: Code Erweiterungen -> LeitsystemXML Agent: LesePersonen - |+Error$
    Resume ExitFunction
End Function