Frage zu "On Error Goto:"

Muesly · 19. April 2004

Hallo zusammen,

ich möchte beim Speichern eines Dokuments ggf. auch daten in einem anderen bestehenden Dokument ändern. Probleme macht mir das nur wenn das zweite Dokument (einer anderen Datenbank) gelöscht wurde. Das hab über ein On Error gelöst:

Code

On Error Goto TerminDeletedSet doc = dbmail.GetDocumentByUNID(UID)...TerminDeleted:...

Das ganze klappt auch wunderbar, nur hab ich das selbe ein paar Zeilen weiter nochmal

Code

On Error Goto ETerminDeleted
Set doc = dbmail.GetDocumentByUNID(UID)
...
ETerminDeleted:
...

Wurde nur der Termin gelöscht funktioniert das skript.
Wurde nur der ETermin gelöscht funktionert das skript auch.
Wurden aber beide gelöscht funktionierts nicht mehr. (der zweite teil liefert eine "Invalid Universal ID".

Warum kann ich nur ein ON ERROR GOTO machen? Was mach ich falsch?
Kann ich das irgendwie anders abfangen??? (goto's sind ja nicht so elegant, weiß mir aber nicht anders zu helfen)

in C++ kenn ich das hald so:
try { ...} catch(...) {}
aber sowas gibts hier ja leider nicht...

Irgendwelche Ideen???

Danke soweit!!!

PlanetX · 22. April 2004

So wie ich das sehe brauchst Du hier kein on Error goto.

Du willst doch wissen, ob das folgende Dok existiert oder nicht?
>> Set doc = dbmail.GetDocumentByUNID(UID)

Da würde also ein

If Not doc Is Nothing Then
--- mache was
End If

reichen.

taurec · 23. April 2004

So einfach ist es leider nicht.

Wenn die übergebene UNID ungültig oder nicht vorhanden ist wirft die Funktion GetDocumentByUNID schon einen Fehler, also kommt das Script nie zu der Überprüfung

PlanetX · 23. April 2004

Danke, Taurec, für den Hinweis. Du hast Recht, da hab ich "zu schnell" gedacht.

Hier kann man übrigens einiges über's ErrorHandling nachlesen:
http://www.lotusgeek.com/Sapph…og.nsf/plinks/ROLR-5MXR69

Grundsätzlich:
"On Error Goto A" hält immer so lange, bis ein "On Error Goto B" folgt. "On Error Goto B" hebt also "On Error Goto A" auf, wenn dieses nach "On Error Goto A" im Code folgt.

Poste mal Deinen ganzen Code.

Muesly · 26. April 2004

Zitat

Grundsätzlich:
"On Error Goto A" hält immer so lange, bis ein "On Error Goto B" folgt. "On Error Goto B" hebt also "On Error Goto A" auf, wenn dieses nach "On Error Goto A" im Code folgt.

Und genau das ist eben nicht so

Hier die Source:

Code

Sub Querysave(Source As Notesuidocument, Continue As Variant)
' TERMIN IN KALENDER EINTRAGEN	
Dim workspace As New NotesUIWorkspace
Dim picklist As Variant
Dim session As New NotesSession
Dim reg As New NotesRegistration
Dim db As NotesDatabase
Dim dbmail As NotesDatabase
Dim doc As NotesDocument
Dim docmail As NotesDocument
Dim docansw As NotesDocument
Dim dochaupt As NotesDocument
Dim doccol As notesdocumentcollection
Dim ndt As NotesDateTime
Dim rti As NotesRichTextItem
Dim index As Integer
Dim cnt As Integer
Dim Temp As String

reg.RegistrationServer = "OTTNOTES1"
Call reg.GetUserInfo(session.UserName, , mailfile$)

Set dbmail = session.Getdatabase("", mailfile$,False) 


' 1. Termin wenn hacken gesetzt	
If Source.Document.DatumInKalenderTermin(0)="Termin" Then	
' Wenns schon einen Eintrag gibt, passen wir dessen Datum an	
If Source.Document.RefTerminEintrag(0)<> "" Then

[b]On Error Goto TerminDeleted[/b]

Set doc = dbmail.GetDocumentByUNID(Source.Document.RefTerminEintrag(0))

Set ndt = New NotesDateTime(Source.Document.Termin(0) + " 08:00")
doc.StartDate  = ndt.LSLocalTime
doc.CalendarDateTime = ndt.LSLocalTime
doc.StartDateTime  = ndt.LSLocalTime
doc.EndDate = ndt.LSLocalTime
doc.EndDateTime = ndt.LSLocalTime
Call doc.Save( True, True )			


Else
[b]TerminDeleted:[/b]
'Neuen Eintrag Termin			

Set doc = dbmail.CreateDocument	


doc.Form = "Appointment"
doc.Subject = "IT Termin: " + Source.Document.Thema(0)
doc.AppointmentType = "4"
Set ndt = New NotesDateTime(Source.Document.Termin(0) + " 08:00")
'	Set ndt2 = New NotesDateTime(Source.Document.Termin(0))
doc.StartDate  = ndt.LSLocalTime
doc.CalendarDateTime = ndt.LSLocalTime
doc.StartDateTime  = ndt.LSLocalTime
doc.EndDate = ndt.LSLocalTime
doc.EndDateTime = ndt.LSLocalTime



Set rti = New NotesRichTextItem( doc, "Body" )
Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
Call doc.ComputeWithForm(True, False)		
Call doc.Save( True, True )	



Messagebox "Termineintrag am " + Source.Document.Termin(0) + " ist erfolgt"

End If
End If		



' 2. E Termin wenn hacken gesetzt		
If Source.Document.DatumInKalenderETermin(0)="Erinnerungsdatum" Then	
' Wenns schon einen Eintrag gibt, passen wir dessen Datum an
If Source.Document.RefETerminEintrag(index)<> "" Then

[b]On Error Goto ETerminDeleted[/b]
Set doc = dbmail.GetDocumentByUNID(Source.Document.RefETerminEintrag(index))
Set ndt = New NotesDateTime(Source.Document.ETermin(0) + " 08:00")
doc.StartDate  = ndt.LSLocalTime
doc.CalendarDateTime = ndt.LSLocalTime
doc.StartDateTime  = ndt.LSLocalTime
doc.EndDate = ndt.LSLocalTime
doc.EndDateTime = ndt.LSLocalTime
Call doc.Save( True, True )				
Else
'Neuen Eintrag ETermin		
[b]ETerminDeleted:[/b]
Set doc = dbmail.CreateDocument	

doc.Form = "Appointment"
doc.Subject = "IT Erinnerung: " + Source.Document.Thema(0)
doc.AppointmentType = "4"
Set ndt = New NotesDateTime(Source.Document.ETermin(0) + " 08:00")
'	Set ndt2 = New NotesDateTime(Source.Document.ETermin(0))
doc.StartDate  = ndt.LSLocalTime
doc.CalendarDateTime = ndt.LSLocalTime
doc.StartDateTime  = ndt.LSLocalTime
doc.EndDate = ndt.LSLocalTime
doc.EndDateTime = ndt.LSLocalTime

Set rti = New NotesRichTextItem( doc, "Body" )
Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
Call doc.ComputeWithForm(True, False)		
Call doc.Save( True, True )	

Messagebox "Errinerungstermineintrag am " + Source.Document.ETermin(0) + " ist erfolgt"

End If	
End If	
End Sub

Alles anzeigen

lodsnods · 26. April 2004

Hi,

ich habe 2 Lösungsansätze für Dich:

1. statt "On Error Goto Irgendwohin" kannst Du auch "on Error Goto Next" nehmen. Dann sollte auch das bereit erwähnte "if not(doc is nothing) ..." funktionieren.

2. bau Dir eine Ansicht, die alle Deinen gewünschten Dokumente enthält und nach der DOK-ID sortiert ist. Mach dort ein dblookup drauf und schau nach, ob Dein Dok noch/schon dabei ist ...

Ronka · 26. April 2004

Deine vorgehensweise ist übrigens sehr gefährlich, den ELSE direkt zu verwenden für den On Error... dieses on error statement schiebt nämlich daten auf den stack der nur mittels resume wieder verwertet werden, welches in dein fall bedeutet das den stack nie befreit wird, und damit dein system in einen zustand kommt der er erst beim beenden des script wieder aufräumen kann... unter umständen kann diese art der programmierung (hier glücklicherweise nicht weil begrenzte dokument zahl) in ersthafte problemen kommen, RBOD nicht ausgeschlossen.
Eine On Error sollte in einem eigenen abschnitt verfolgt werden, und mittels Resume Label oder Resume next wieder im programm zurück kommen... den vorgehensweise ist vorgelegt, und sollte iengehalten werden, nicht von mir sondern vom programmiersprache her.

Muesly · 30. April 2004

Grosses Dankeschön an alle, konnte das problem lösen.

Für interessierte hier nun die komplette Source:

Code

Sub Querysave(Source As Notesuidocument, Continue As Variant)
	' TERMIN IN KALENDER EINTRAGEN	
	Dim workspace As New NotesUIWorkspace
	Dim picklist As Variant
	Dim session As New NotesSession
	Dim reg As New NotesRegistration
	Dim db As NotesDatabase
	Dim dbmail As NotesDatabase
	Dim doc As NotesDocument
	Dim doc2 As NotesDocument
	Dim docmail As NotesDocument
	Dim docansw As NotesDocument
	Dim dochaupt As NotesDocument
	Dim doccol As notesdocumentcollection
	Dim ndt As NotesDateTime
	Dim rti As NotesRichTextItem
	Dim index As Integer
	Dim cnt As Integer
	Dim Temp As String
	Dim CreateNewTermin As Boolean
	Dim CreateNewETermin As Boolean

	CreateNewTermin = False
	CreateNewETermin = False


	reg.RegistrationServer = ""
	Call reg.GetUserInfo(session.UserName, , mailfile$)

	Set dbmail = session.Getdatabase("", mailfile$,False) 

	[b]On Error Resume Next[/b]

' 1. Termin wenn hacken gesetzt	
	If Source.Document.DatumInKalenderTermin(0)="Termin" Then	

' Wenns schon einen Eintrag gibt, passen wir dessen Datum an	
		If Source.Document.RefTerminEintrag(0)<> "" Then

'			On Error Resume Next

			Set doc = dbmail.GetDocumentByUNID(Source.Document.RefTerminEintrag(0))

			' Feststellen ob das Dokument noch existiert
			[b]If Not (doc Is Nothing) Then[/b]

				doc.Form = "Appointment"
				doc.Subject = "IT Termin: " + Source.Document.Thema(0)
				doc.AppointmentType = "4"
				Set ndt = New NotesDateTime(Source.Document.Termin(0) + " 08:00")
				doc.StartDate  = ndt.LSLocalTime
				doc.CalendarDateTime = ndt.LSLocalTime
				doc.StartDateTime  = ndt.LSLocalTime
				doc.EndDate = ndt.LSLocalTime
				doc.EndDateTime = ndt.LSLocalTime
				Set rti = New NotesRichTextItem( doc, "Body" )
				Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
				Call doc.ComputeWithForm(True, False)		
				Call doc.Save( True, True )			

			Else
				' Existiert das Dokument nicht mehr legen wir es an
				CreateNewTermin = True
			End If	
		Else
			' Existiert das Dokument noch nicht legen wir es auch an
			CreateNewTermin = True
		End If	

'Dokument bei bedarf anlegen		
		If CreateNewTermin = True Then		

			Set doc = dbmail.CreateDocument				
			doc.Form = "Appointment"
			doc.Subject = "IT Termin: " + Source.Document.Thema(0)
			doc.AppointmentType = "4"
			Set ndt = New NotesDateTime(Source.Document.Termin(0) + " 08:00")
'	Set ndt2 = New NotesDateTime(Source.Document.Termin(0))
			doc.StartDate  = ndt.LSLocalTime
			doc.CalendarDateTime = ndt.LSLocalTime
			doc.StartDateTime  = ndt.LSLocalTime
			doc.EndDate = ndt.LSLocalTime
			doc.EndDateTime = ndt.LSLocalTime

			Set rti = New NotesRichTextItem( doc, "Body" )
			Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
			Call doc.ComputeWithForm(True, False)		
			Call doc.Save( True, True )	

			Source.Document.RefTerminEintrag = doc.UniversalID

			Messagebox "Termineintrag am " + Source.Document.Termin(0) + " ist erfolgt"

		End If
	End If		

' 2. E Termin wenn hacken gesetzt		
	If Source.Document.DatumInKalenderETermin(0)="Erinnerungsdatum" Then	
' Wenns schon einen Eintrag gibt, passen wir dessen Datum an
		If Source.Document.RefETerminEintrag(0)<> "" Then

'			On Error Resume Next
			Set doc2 = dbmail.GetDocumentByUNID(Source.Document.RefETerminEintrag(0))

  		    ' Feststellen ob das Dokument noch existiert
			[b]If Not (doc2 Is Nothing) Then[/b]

				Set ndt = New NotesDateTime(Source.Document.ETermin(0) + " 08:00")
				doc2.StartDate  = ndt.LSLocalTime
				doc2.CalendarDateTime = ndt.LSLocalTime
				doc2.StartDateTime  = ndt.LSLocalTime
				doc2.EndDate = ndt.LSLocalTime
				doc2.EndDateTime = ndt.LSLocalTime
				Set rti = New NotesRichTextItem( doc2, "Body" )
				Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
				Call doc2.ComputeWithForm(True, False)		
				Call doc2.Save( True, True )				

			Else
				CreateNewETermin = True
			End If	
		Else
			CreateNewETermin = True
		End If	

		If 	CreateNewETermin = True Then
'Neuen Eintrag ETermin		

			Set doc2 = dbmail.CreateDocument	

			doc2.Form = "Appointment"
			doc2.Subject = "IT Erinnerung: " + Source.Document.Thema(0)
			doc2.AppointmentType = "4"
			Set ndt = New NotesDateTime(Source.Document.ETermin(0) + " 08:00")
'	Set ndt2 = New NotesDateTime(Source.Document.ETermin(0))
			doc2.StartDate  = ndt.LSLocalTime
			doc2.CalendarDateTime = ndt.LSLocalTime
			doc2.StartDateTime  = ndt.LSLocalTime
			doc2.EndDate = ndt.LSLocalTime
			doc2.EndDateTime = ndt.LSLocalTime

			Set rti = New NotesRichTextItem( doc2, "Body" )
			Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
			Call doc2.ComputeWithForm(True, False)		
			Call doc2.Save( True, True )	

			Source.Document.RefETerminEintrag = doc2.UniversalID

			Messagebox "Errinerungstermineintrag am " + Source.Document.ETermin(0) + " ist erfolgt"

		End If	
	End If	
End Sub

Alles anzeigen

MPerio · 1. Mai 2004

on error goto next verwende ich wirklich nur in ausnahme fällen und nur für kurze Codesegmente, da dadurch unerwünschte nebeneffekte auftreten können. Wenn z. B. ein Datenbank Objekt nicht initialisiert werden konnte, werden alle Operationen mit diesem Objekt zu einem Fehler führen und er läuft jedesmal in die Fehler-Routine.

Ich verwende meistens folgende Syntax:

sub XY
on error goto Fehler
..... code ....

if err <> 0 then
print Err$ 'or something else
end if
sub end

Muesly · 4. Mai 2004

Hi MPerio,
danke für den hinweis, gefällt mir auch besser so:

Code

Function GetDocByID (ID As String, dbmail As NotesDatabase) As NotesDocument	On Error Resume Next	Set GetDocbyID = dbmail.GetDocumentByUNID(ID)	End Function

Code

Sub Querysave(Source As Notesuidocument, Continue As Variant)
	' TERMIN IN KALENDER EINTRAGEN	
	Dim workspace As New NotesUIWorkspace
	Dim picklist As Variant
	Dim session As New NotesSession
	Dim reg As New NotesRegistration
	Dim db As NotesDatabase
	Dim dbmail As NotesDatabase
	Dim doc As NotesDocument
	Dim doc2 As NotesDocument
	Dim docmail As NotesDocument
	Dim docansw As NotesDocument
	Dim dochaupt As NotesDocument
	Dim doccol As notesdocumentcollection
	Dim ndt As NotesDateTime
	Dim rti As NotesRichTextItem
	Dim index As Integer
	Dim cnt As Integer
	Dim Temp As String
	Dim CreateNewTermin As Boolean
	Dim CreateNewETermin As Boolean



	CreateNewTermin = False
	CreateNewETermin = False


	reg.RegistrationServer = ""
	Call reg.GetUserInfo(session.UserName, , mailfile$)

	Set dbmail = session.Getdatabase("OTTNOTES1/Ott Messtechnik/DE", mailfile$,False) 



' 1. Termin wenn hacken gesetzt	
	If Source.Document.DatumInKalenderTermin(0)="Termin" Then	

' Wenns schon einen Eintrag gibt, passen wir dessen Datum an	
		If Source.Document.RefTerminEintrag(0)<> "" Then

			Set doc = GetDocByID(Source.Document.RefTerminEintrag(0), dbmail)

			' Feststellen ob das Dokument noch existiert
			If Not (doc Is Nothing) Then

				doc.Form = "Appointment"
				doc.Subject = "IT Termin: " + Source.Document.Thema(0)
				doc.AppointmentType = "4"
				Set ndt = New NotesDateTime(Source.Document.Termin(0) + " 08:00")
				doc.StartDate  = ndt.LSLocalTime
				doc.CalendarDateTime = ndt.LSLocalTime
				doc.StartDateTime  = ndt.LSLocalTime
				doc.EndDate = ndt.LSLocalTime
				doc.EndDateTime = ndt.LSLocalTime
				Set rti = New NotesRichTextItem( doc, "Body" )
				Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
				Call doc.ComputeWithForm(True, False)		
				Call doc.Save( True, True )			

			Else
				' Existiert das Dokument nicht mehr legen wir es an
				CreateNewTermin = True
			End If	
		Else
			' Existiert das Dokument noch nicht legen wir es auch an
			CreateNewTermin = True
		End If	

'Dokument bei bedarf anlegen		
		If CreateNewTermin = True Then		

			Set doc = dbmail.CreateDocument				
			doc.Form = "Appointment"
			doc.Subject = "IT Termin: " + Source.Document.Thema(0)
			doc.AppointmentType = "4"
			Set ndt = New NotesDateTime(Source.Document.Termin(0) + " 08:00")
'	Set ndt2 = New NotesDateTime(Source.Document.Termin(0))
			doc.StartDate  = ndt.LSLocalTime
			doc.CalendarDateTime = ndt.LSLocalTime
			doc.StartDateTime  = ndt.LSLocalTime
			doc.EndDate = ndt.LSLocalTime
			doc.EndDateTime = ndt.LSLocalTime

			Set rti = New NotesRichTextItem( doc, "Body" )
			Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
			Call doc.ComputeWithForm(True, False)		
			Call doc.Save( True, True )	

			Source.Document.RefTerminEintrag = doc.UniversalID

			Messagebox "Termineintrag am " + Source.Document.Termin(0) + " ist erfolgt"

		End If
	End If		

' 2. E Termin wenn hacken gesetzt		
	If Source.Document.DatumInKalenderETermin(0)="Erinnerungsdatum" Then	
' Wenns schon einen Eintrag gibt, passen wir dessen Datum an
		If Source.Document.RefETerminEintrag(0)<> "" Then

			Set doc2 = GetDocByID(Source.Document.RefETerminEintrag(0), dbmail)

  		    ' Feststellen ob das Dokument noch existiert
			If Not (doc2 Is Nothing) Then

				Set ndt = New NotesDateTime(Source.Document.ETermin(0) + " 08:00")
				doc2.StartDate  = ndt.LSLocalTime
				doc2.CalendarDateTime = ndt.LSLocalTime
				doc2.StartDateTime  = ndt.LSLocalTime
				doc2.EndDate = ndt.LSLocalTime
				doc2.EndDateTime = ndt.LSLocalTime
				Set rti = New NotesRichTextItem( doc2, "Body" )
				Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
				Call doc2.ComputeWithForm(True, False)		
				Call doc2.Save( True, True )				

			Else
				CreateNewETermin = True
			End If	
		Else
			CreateNewETermin = True
		End If	

		If 	CreateNewETermin = True Then
'Neuen Eintrag ETermin		

			Set doc2 = dbmail.CreateDocument	

			doc2.Form = "Appointment"
			doc2.Subject = "IT Erinnerung: " + Source.Document.Thema(0)
			doc2.AppointmentType = "4"
			Set ndt = New NotesDateTime(Source.Document.ETermin(0) + " 08:00")
'	Set ndt2 = New NotesDateTime(Source.Document.ETermin(0))
			doc2.StartDate  = ndt.LSLocalTime
			doc2.CalendarDateTime = ndt.LSLocalTime
			doc2.StartDateTime  = ndt.LSLocalTime
			doc2.EndDate = ndt.LSLocalTime
			doc2.EndDateTime = ndt.LSLocalTime

			Set rti = New NotesRichTextItem( doc2, "Body" )
			Call rti.AppendDocLink(Source.Document, Source.Document.Thema(0))			
			Call doc2.ComputeWithForm(True, False)		
			Call doc2.Save( True, True )	

			Source.Document.RefETerminEintrag = doc2.UniversalID

			Messagebox "Errinerungstermineintrag am " + Source.Document.ETermin(0) + " ist erfolgt"

		End If	
	End If	
End Sub

Alles anzeigen

Teilen