Tach auch!
Ich will mir ein Script schreiben, dass bei jeder DB nachsieht, ob die Option, dass die DB im Open Database-Dialog erscheint, gesetzt ist. Mit der "ListInDbCatalog"-Property funzt das ja einwandfrei. Ich hatte gehofft, ich könnte das alles in einem Aufwasch machen, anstattg erst den Agenten abzufeuern und hinterher doch alle DBs manuell durchzugehen...
Diese Option kann ich per DB-Eigenschaftenfenster ja ändern. Aber wie geht das per Script?
thx in advance
RW
Wie hast du das versucht mit den script Oder hast du aufgegeben nach dieses schreiben ?
Mahlzeit!
Ronka: ich habs aufgegeben...
Diali: die ListInDbCatalog-Property ist mir ja bekannt. Damit kann ich ja wunderbar rumspielen, aber zusätzlich zu dieser Property will ich halt, dass DBs auch im DatabaseOpen-Dialog auftauchen; eben nicht nur im catalog. Ich dachte da an so eine Art von DbShowInDialog-Property (analog zum Feldnamen im catalog, aber wie die Property heißt ist ja im Grunde egal)...
greetz
RW
Dies geht nur über die API.
Den Code verwende ich mit Notes 5.x unter Win32.
(Declarations)
Const APIModule = "NNOTES" ' Windows/32 only
Const REPLFLG_DO_NOT_BROWSE = &H0400
Type ReplicaInfo
ID(1) As Long
Flags As Integer
CutoffDays As Integer
CutoffDate(1) As Long
End Type
Declare Function NSFDbOpen Lib APIModule Alias "NSFDbOpen" ( Byval P As String, H As Long) As Integer
Declare Function NSFDbClose Lib APIModule Alias "NSFDbClose" ( Byval H As Long) As Integer
Declare Function OSPathNetConstruct Lib APIModule Alias "OSPathNetConstruct" ( Byval Z As Long, Byval S As String, Byval F As String, Byval P As String) As Integer
Declare Function NSFDbReplicaInfoGet Lib APIModule Alias "NSFDbReplicaInfoGet" ( Byval H As Long, R As ReplicaInfo) As Integer
Declare Function NSFDbReplicaInfoSet Lib APIModule Alias "NSFDbReplicaInfoSet" ( Byval H As Long, R As ReplicaInfo) As Integer
' Beispiel Script
Dim hDB As Long
Dim session As New NotesSession
Dim db As NotesDatabase
Set db = session.CurrentDatabase
p$ = String(1024, " ")
OSPathNetConstruct 0, db.Server, db.FilePath, p$
NSFDbOpen p$, hDB
Dim R As ReplicaInfo
NSFDbReplicaInfoGet hDB, R
R.Flags = R.Flags And Not REPLFLG_DO_NOT_BROWSE ' Haken setzen
' R.Flags = R.Flags Or REPLFLG_DO_NOT_BROWSE ' Haken löschen
NSFDbReplicaInfoSet hDB, R
NSFDbClose hDB