Kalendereinträge neu speichern

Hallo zusammen,

wir haben das Problem, dass Kalendereinträge, die auf einem PDA erstellt werden, in der Tagesansicht falsch angezeigt werden. Gleiches Problem tritt auch auf, wenn Termine auf dem PDA geändert werden.
Öffnet man diesen Termin im Notes und speichert ihn einfach noch einmal ab, so wird der Termin in der Zeitskala richtig angezeigt.
Ich habe auch noch einen Thread mit diesem Problem gefunden: http://atnotes.de/index.php?topic=38073.msg240698

Ein Patch der Herstellerfirma ist angekündigt. Leider werden damit wahrscheinlich nicht die schon "verbogenen" Einträge korrigiert, sondern nur das Problem behoben.

Nun habe ich gedacht, dass ich über einen Agenten, der die Dokumente einfach noch einmal abspeichert, das Problem mit der Anzeige in der Zeitskala in den Griff bekommen kann. Mein Agent ist nachstehend angegeben. Er bearbeitet auch alle Dokumente. Jedoch werden diese weiterhin in der Zeitskala falsch angezeigt.
Hat noch jemand eine Idee?

Viele Grüße

Christian

Sub Initialize
	Dim session As New NotesSession
	Dim db As NotesDatabase
	Dim dc As NotesDocumentCollection
	Dim doc As NotesDocument
	Dim tmpdoc As NotesDocument
	Dim success As Variant
	Set db = session.CurrentDatabase


	Print "Zu bearbeitende Dokumente werden gesucht...."
	Set dc = db.Search( {Form = "Appointment"}, Nothing ,0)
	Set doc = dc.GetFirstDocument()
	While Not(doc Is Nothing)
		Print "Eintrag " & doc.Subject(0) & " wird bearbeitet... "	
		success = doc.ComputeWithForm( False, False )
		If success Then
			Call doc.Save( True, True )
		End If
		Set doc = dc.GetNextDocument(doc)
	Wend
	Print "Der Vorgang wurde abgeschlossen...."
End Sub

Hallo Dirk,

vielen Dank für den Hinweis. Das war mir so nicht klar. (Bin aber auch kein Entwickler....)

Ich habe noch einmal etwas im "IBM Lotus Notes Calendaring & Scheduling Schema" nachgelesen. Dort steht folgendes:

Zitat

OrgTable:
Text:
This item is used to tell Lotus Organizer in which section an entry should be displayed. Since Organizer can have > 1 calendar, Notes defaults to using the first one by ALWAYS putting a "C0" into this item.

Möchte man wissen, wieviele Dokumente "einen Schlag" haben, so kann man sich eine Ansicht bauen. Ich habe die "($Meetings)" kopiert und die Ansichtsauswahl auf

SELECT Form = "Appointment" : "Notice" & OrgTable = "P0" & AppointmentType != "2" | @AllDescendants

geändert.

Meine Lösung sieht nun so aus: ich suche mir die Dokumente, die OrgTable(0) = "P0" und AppointmentType(0) = "2" haben. Bei diesen wird dann das Feld OrgTable auf "C0" gesetzt.

Sub Initialize
	' Code ist quick and dirty
	' Benutzung auf eigene Gefahr!!!
	Dim session As New NotesSession
	Dim item As NotesItem
	Dim db As NotesDatabase
	Dim dc As NotesDocumentCollection
	Dim doc As NotesDocument
	Dim success As Variant
	Dim i As Integer
	Set db = session.CurrentDatabase
	i = 0

	Print "Zu bearbeitende Dokumente werden gesucht...."
	Set dc = db.Search( {Form = "Appointment"}, Nothing ,0)
	Set doc = dc.GetFirstDocument()
	While Not(doc Is Nothing)
		If doc.OrgTable(0) = "P0" Then
			If doc.AppointmentType(0) = "2" Then
				Print "Eintrag " & doc.Subject(0) & " übersprungen... "
			Else
				doc.OrgTable = "C0"
				Print "Untersuche Eintrag " & doc.Subject(0) 
				success = doc.ComputeWithForm( False, False )
				Print "Eintrag " & doc.Subject(0) & " bearbeitet... "
				Call doc.Save( True, True )
				i = i + 1
			End If
		End If
		Set doc = dc.GetNextDocument(doc)
	Wend
	Print "Es wurden " & i & " Einträge bearbeitet"
End Sub

Der Code ist sicherlich quick and dirty. Bei mir funktioniert er unter 6.5.5. Bisher sind keine Probleme zu erkennen. Trotzdem geschieht der Einsatz auf eigene Gefahr!!!

Viele Grüße

Christian