Wie Logdatei einlesen und zeilenweise aufteilen?

Bahula · 31. Januar 2006

Hallo Leute,

habe folgendes Problem.

Ich habe eine nsf Datei die ich einlese. In der nsf sind Zeileneinträge untereinander angeordnet.
Ich möchte jetzt das ich jede Zeile einzelen ansprechen kann. Das funktioniert aber leider nicht. Ich kann lediglich den ganzen Text einlesen.

Auf mit Zeilenumbrüchen Chr(013)+Chr(010) kann ich den Text leider auch nicht aufteilen. Keine Ahnung aber wenn ich den Text mit einem left Befehl einschränken will bis zum Zeilenumbruch gibt er mir immer "" zurück.

Was gibts da für eine Möglichkeit das ganze aufzuteilen?
Im Notes 6 ist das von den Einträgen her schon aufgeteilt aber im 5er nicht.

Hoffe ihr könnt mir wieder helfen.

mfg Bahula

EDIT: So lese ich die Datei ein.

tmp1 =Evaluate("@left(@lowercase(Events);@lowercase("+Chr(034)+Events+Chr(034)+"))",doc)

bis zu der Stelle wo ein Eintrag Events vorkommt.
Ich brauche jetzt die komplette Zeile in der der Eintrag von Events vorkommt aber wie bekomm ich die wenn der irgendwo in der Zeile steht?
das erste Events liest mir den log und das zweite Events ist der Begriff nach dem gesucht wird.

bofh · 31. Januar 2006

Eine NSF-Datei hat keine Zeileneinträge, eine NSF-Datei ist eine binäre Datei.

Ein Notes-Dokument hat RT- und Textfelder, welche mehrere Zeilen Text beinhalten können.

Daher: Auf welche Felder greifst Du zu und in welcher Sprache willst Du das lösen?

Bahula · 31. Januar 2006

Ist Lotus Script im Designer 5.

Feldname: Events
Datentyp: Textliste
Datenlänge: 40012 Byte
Seq.-Num.: 4
Doppelte Eintrags-ID: 0
Feld-Flags:

das sind die Daten vom Feld auf das ich zugreife.

EDIT:
Ich hab vor jeder Zeile so einen Zeiteintrag:
31.01.2006 07:04:04
Kann ich nach diesem eventuell trennen? Gibts vielleicht einen Zeitbefehl der überprüft ob ein eintrag ein gewisses Zeitformat hat?

DerOzzy · 31. Januar 2006

Ich nehme mal an, du willst einen Eintrag aus der Log.nsf in die einzelnen Zeilen zerlegen ?

Wir haben so was im Einsatz, schreiben die MiscEvents in eine Textdatei, die dann geparsed wird.

Das geht so (hier nur der Teil des Codes, der für Dich interessant sein dürfte):

Dein Logdokument übergibst du an doc.

Code

Sub logexport ( doc As NotesDocument)

	Dim var As Variant
	var = doc.GetItemValue("Events")
	If Isarray( var) Then
		Forall x In var
			Print #file, x
		End Forall
	Else
                Print #file, var
End Sub

Alles anzeigen

Natürlich kannst Du mit dem Inhalt von x auch andere Dinge anstellen, als in ein Textfile zu schreiben.

Gruß

Ozzy

Bahula · 31. Januar 2006

wenn ich das einfüge dann schreibt er mir für x auch wieder den kompletten Text vom Log raus.

dnotes · 31. Januar 2006

Natuerlich....steht ja auch alles in einer "Zeile" in dem Feld.

bofh · 31. Januar 2006

Wenn Events ein Multivalue-Field wäre, könntest Du einfach:
doc.Events(0) <= Erste Zeile
doc.Events(1) <= Zweite Zeile
doc.Events(2) <= Dritte Zeile

Wenn es kein Multivalue-Field ist:

Code

Dim strarray As Variant

strarray = Split( doc.Events(0), Chr$(13) & Chr$(10) )
Messagebox strarray(1),,"Zeile 2"

Bahula · 31. Januar 2006

"illegal parenthesized reference: SPLIT"

Kann das sein dass das die 5er Version wieder nicht kann?

mfg Bahula

dnotes · 31. Januar 2006

Split ist erst ab 6 verfuegbar.#
Ausserdem denke ich, dass das Feld Event nie MultiValue ist. Aber das sit eine Vermutung; ich kann nicht alle Logs ueberpruefen

bofh · 31. Januar 2006

Ah damn. Dann nimm halt das Split aus der CodeBin von OpenNTF.

Bahula · 31. Januar 2006

da hast du recht, es ist kein MultiValue sonst würds schön gehen ist aber nicht.

Wie könnte ich die dann trennen? Gibts noch eine andere Möglichkeit?

mfg Bahula

Edit:
Kann ich das split dann genau so verwenden wie oben beschrieben?

Diali · 31. Januar 2006

oder teile den Eintrag mit Split auf ein Array auf.

Gruß
Dirk

%edit
Ok bei Version 5.x nachbauen mit instr und Left.

Bahula · 31. Januar 2006

geile Seite dieses OpenNTF

Diali
was wie wo?

Bahula · 31. Januar 2006

Gibts da ne Vorlagefunktion fürs aufteilen in arrays?

Diali · 31. Januar 2006

nadu könntest den String mit Instr() auf Trennzeichen prüfen und wenn eins vorhanden ist mit Left die ersten x Zeichen abschneiden und in ein Array schreiben. Danach ruft du mit dem gekürzten String die Funktion so lange auf, bis instr leer ist.

Gruß
Dirk

ascabg · 31. Januar 2006

Hi,

Wenn Du mit "instr" arbeitest, dann kennst Du also das Zeichen nach dem Du trennen (aufteilen moechtest)

In diesem Fall koennte StrLeft(...) eventuell auch weiterhelfen.

Andreas

dnotes · 31. Januar 2006

Mit dieser Funktion geht´s auch:

Code

Function VExplode ( Arg As Variant, Delimiter As Variant) As Variant

	Dim TmpVari As Variant
	Dim TmpCounts() As Integer
	Dim TmpStr As String
	Dim TmpStrIx As Integer
	Dim TmpIx As Integer
	Dim Ix As Integer
	Dim Count As Integer
	Dim Delims As Variant
	Dim DelimChar As String
	On Error Goto Errorhandler

	If Isarray (delimiter) Then
		Delims = Delimiter
	Else
		Redim Delims (0)
		Delims (0) = Cstr(delimiter)
	End If
	DelimChar = Chr(11) '
	If Isarray (Arg) Then
		Redim TmpVari(Ubound(Arg)-Lbound(arg))
		TmpIx = -1
		Forall Item In Arg
			TmpIx=TmpIx+1
			TmpVari(TmpIx) = Item
		End Forall
	Elseif Isempty(Arg) Then 
		Vexplode = Arg
		Exit Function
	Else
		Redim TmpVari(0)
		TmpIx = 0
		TmpVari(TmpIx) = arg
	End If
     '
	Redim TmpCounts(TmpIx)
	TmpIx = -1
	Count = 0
	Forall item In TmpVari
		TmpIx = TmpIx + 1
		TmpCounts(TmpIx) = 0
'
		If Datatype(item) = 8 Then 
			Forall delim In Delims
				If Delim <> "" Then
					While Instr(Item,Delim)>0
						Item = Left(Item,Instr(Item,delim)-1)+DelimChar+Right(Item,Len(Item)-Instr(Item,delim)-Len(Delim)+1)
						TmpCounts(TmpIx)= TmpCounts(TmpIx) + 1
					Wend
				End If
			End Forall
		End If
		Count = Count + TmpCounts(TmpIx)
	End Forall

	Redim Preserve TmpVari (TmpIx+Count)
	Ix = Ubound(TmpVari)
	While Ix >-1
		If ix = TmpIx Then
			Ix=-1
		Else
			If Datatype(TmpVari(TmpIx)) = 8 Then '
				TmpStr = TmpVari(TmpIx)
				Ix = Ix -TmpCounts(TmpIx)
				For TmpStrIx = Ix To Ix + TmpCounts(TmpIx) -1
					TmpVari(TmpStrIX) = Left(TmpStr,Instr(TmpStr,DelimChar)-1)
					TmpStr = Right(TmpStr,Len(TmpStr)-Instr(TmpStr,DelimChar))
				Next TmpStrIx 
				TmpVari(TmpStrIx) = Tmpstr
			Else
				TmpVari(Ix) = TmpVari(TmpIx)
			End If         
			Ix=Ix-1
			TmpIx = TmpIx -1
		End If
	Wend
	Vexplode = TmpVari
	Exit Function
Errorhandler:
	Error Str(Err),  "LibFct - VExplode " + Error$          

End Function

Alles anzeigen

Bahula · 31. Januar 2006

Hab das jetzt mal mit der Split Funktion probiert und auf Chr$(013) & Chr$(010) getrennt aber da trennt er nicht sauber jede Zeile sondern schreibt meist 2 oder 3 Zeilen aneinander.

Wie kann ich das lösen das er jede Zeile nimmt?

mfg Bahula

P.S.: find ich toll das hier so schnell geholfen wird.

dnotes · 31. Januar 2006

Mit
var = doc.GetItemValue("Events")
zeilenweise = VExplode(var,Chr(13))

Bahula · 31. Januar 2006

danke, das mit der VExplode funktioniert echt fein.

mfg Bahula

Wie Logdatei einlesen und zeilenweise aufteilen?

Teilen

Benutzer online in diesem Thema