@Unique Befehl wie anwenden?

Bahula · 17. Januar 2006

Hab diese Formel und muss da den @Unique Befehl anwenden auf das Ergebniss aber wie?
Wenn ich die ganze Formal unter diesen Befehl setze gibt er mir gar nichts zurück, also 0 und wenn er normal ausgeführt wird 514.
Wie kann ich da Unique anwenden oder gibts unter Lotus Scripts einen ähnlichen Befehl?

search2$="@lowercase(Form) = ""local"" & @lowercase(Type) = ""connection"" & @lowercase(Tasks) = ""replication"" &@lowercase(Source) = """ &Trim(Lcase(server)) &""""

Set col3 = db3.Search(search2$,datetime,0)

mfg Bahula

taurec · 17. Januar 2006

Was soll dort dein ein Unique Aufruf überhaupt erreichen ?

Doppelte Ergebnisse rausfiltern wird auf die Art und weise nicht gehen, da zwei Dokumente ja nie gleich sind und bei der Bedingung gibt das meines Erachtens keinen Sinn.

Gib uns doch einmal ein paar zusätzliche Infos

Diali · 17. Januar 2006

ein @Unique funktioniert im Script mit ArrayUnique.

Aber deine Col3 besteht aus Dokumenten, dork kann kein ArrayUnique angewendet werden!.

Gruß
Dirk

Bahula · 18. Januar 2006

die col3 besteht aus Einträgen aus einer Datenbank wo welche zu 100% gleich sind. Wie kann ich die dann raus filtern das ich jeden Eintrag nur einmal habe?

mfg Bahula

dnotes · 18. Januar 2006

Mit col3 bekommst Du ja eine Notesdocumentcollection zurueck. Da musst Du Dich erstmal entscheiden welche Werte Du aus diesen Dokumenten vergleichen willst. Denn die Dokumente selber werden zu 100% nicht in allen Punkten identisch sein.

Diali · 18. Januar 2006

d.h. die Dokumente interessieren dich nicht?

dann lese die Werte aus den Dokumenten in ein Array ein und mach einen ArrayUnique und wenn gewünscht noch einen FullTrim (entfernt leere Einträge) über das Array.

Gruß
Dirk

Bahula · 18. Januar 2006

kannst mir vielleicht ein kleines Beispiel geben?

Ich möchte aus einer Ansicht in einer Spalte suchen und wenn ein Wert vorkommt den Wert einer andern Spalte in dieser Zeile in ein Array schreiben.
Also es soll die ganze Datenbank durchsucht werden und eben nur die Zeilen gesammelt werden die diesen Wert beinhalten.

Diali · 18. Januar 2006

in etwa so

Code

dim array(col3.Count - 1) as String


i = 0 
'Feldwerte aus Col in Array einlesen
set doc = doc3.GetFirstDocument
While not doc is Nothing
  array(i) = doc.FeldNameDessenInhaltDuHabenWillst(0)
  set doc = col3.GetNextDocument(doc)
Wend


' Array eindeutig und ohne leere Einträge
array_res = FullTrim(ArrayUnique(array))

Alles anzeigen

Gruß
Dirk

Bahula · 18. Januar 2006

143: Illegal parenthesized reference: ARRAYUNIQUE

Den Fehler bekomm ich jetzt.

dnotes · 18. Januar 2006

Wie sieht Dein Code aus?

Bahula · 18. Januar 2006

Set db2view = db2.GetView("($NETOnline)")
Set betrdoc =db2view.GetFirstDocument
Set db3 = New NotesDatabase("**************","********")
Set db3view = db3.GetView("(***********)")
Set doc3 =db3view.GetFirstDocument

Dim array3(0 To 800) As String
w = 0

Do Until doc3 Is Nothing
array3(w) = doc3.source(0)
Set doc3 = db3view.GetNextDocument(doc3)
w = w+1
Loop

array3_kompl = Fulltrim(ArrayUnique(array3))

Fehler ist jetzt bei der Zeile aray3_kompl: 131 Illegal parenthesized reference: ARRAYUNIQUE

Bahula · 18. Januar 2006

So bin jetzt drauf gekommen das arrayunique ein 6er Befehl ist und im 5er Designer noch nicht verwendet werden kann.

Gibts im 5er auch einen ähnlichen Befehl der das gleiche macht?

mfg Bahula

Diali · 18. Januar 2006

:hammer: habe das R5.x-Forum übersehen - SORRY :wuet:

In der Designer-Hilfe steht nix davon drin, dass es neu in 6 ist!

Dann musst du das Array erst sortieren (z.B. mit Q-Sort) und dann doppelte entfernen.

Bin mir auch nicht sicher, ob es den FullTrim schon in 5 gab!

Gruß
Dirk

taurec · 18. Januar 2006

Diali

ist zugegebenermassen etwas versteckt aber unter What's new in Domino Designer 6\Programming LotusScript\Lotus Script Language gibt es eine Liste der neuen Befehle in LotusScript

Bahula · 18. Januar 2006

nicht schlagen aber wie nehm ich bei LotusScript den Q-sort her?
Kenn das nur von C++ und beim Script schauts scheinbar anders aus. Die Hilfe sagt mir da auch nichts.

Diali · 18. Januar 2006

taurec
ja aber im Dokument zu ArrayUnique steht es nicht. Bei (fast) allen anderen steht es direkt dort.

Zitat

nicht schlagen aber wie nehm ich bei LotusScript den Q-sort her?

selber bauen! oder lieb bitte sagen

Code

(Declarations)
Type stacktype
	low As Integer
	hi As Integer
End Type


Sub QuickSort(sArray As Variant)
' iterativ
	Dim lower As Long
	Dim upper As Long
	Dim hi As Long
	Dim low As Long
	Dim mid_ As Long
	Dim i As Long
	Dim j As Long
	Dim sp As Long
	Dim compare_ As Variant
	Dim swap As Variant 
	Dim lstack(1 To 128) As stacktype

	lower = Lbound(sArray)
	upper = Ubound(sArray)

	sp = 1

	lstack(sp).low = lower
	lstack(sp).hi = upper
	sp = sp + 1

	Do
		sp = sp - 1
		low = lstack(sp).low
		hi = lstack(sp).hi
		Do
			i = low
			j = hi
			mid_ = (low + hi) \ 2
			compare_ = sArray(mid_)
			Do
				Do While sArray(i) < compare_
					i = i + 1
				Loop
				Do While sArray(j) > compare_
					j = j - 1
				Loop
				If i <= j Then
					swap = sArray(j)
					sArray(j) = sArray(i)
					sArray(i) = swap
					i = i + 1
					j = j - 1
				End If
			Loop While i <= j
			If j - low < hi - i Then
				If i < hi Then

					lstack(sp).low = i
					lstack(sp).hi = hi
					sp = sp + 1
				End If
				hi = j
			Else
				If low < j Then
					lstack(sp).low = low
					lstack(sp).hi = j
					sp = sp + 1
				End If
				low = i
			End If
		Loop While low < hi 
	Loop While sp <> 1

End Sub

Alles anzeigen

Bahula · 18. Januar 2006

tjo dann werd ich mir das mal selber schreiben. Arrayunique wäew da schon ganz fein gewesen aber was solls.

dnotes · 18. Januar 2006

Oder etwas uebersichtlicher:
Einfach die Funktion aufrufen mit

Unique = atUnique(Fulltrim(array3),True)

Code

Function atUnique(a, Byval caseflag%) As Variant
' a ist das Array. Es kommt das "unique" Array zurueck

' das caseflag argument ist True fuer case-sensitive Vergleich
	Dim data List As Integer
	Dim i%, n%

	For i=Lbound(a) To Ubound(a)
		If caseflag Then data( Cstr(a(i)) ) = i Else data( Lcase(Cstr(a(i))) ) = i

	Next


	Redim newarray(0 To Ubound(a)-Lbound(a)) 
	Forall z In data
		newarray(n) = a(z) 
		n = n + 1
	End Forall
	Redim Preserve newarray(0 To n-1) 

	atUnique = newarray
End Function

Alles anzeigen

Diali · 18. Januar 2006

Zitat

tjo dann werd ich mir das mal selber schreiben

:-? :-? :-? :-? :-? :-? :-? :-? :-? :-? :-? :-? :-? :-? :-? :-?

den Q-Sort (QuickSort) habe ich doch fertig angehangen.

gruß
Dirk

dnotes · 18. Januar 2006

Vielleicht wollte er es nicht sortieren sondern jeden Wert nur einmal haben.

Teilen