XML auswerten

Codde · 9. August 2005

Hallo,

Ich kenn mich mit XML überhaupt nicht aus, deshalb kann's auch sein, dass die Lösung für mein Problem ganz banal ist.

Ich hab einen XML-Baum, der in etwa so aussieht:

oder

<input>
<form name="form">formname</form>
<data>
<value name="feldname 1">inhalt feld 1</value>
<value name="feldname 2">inhalt feld 2</value>
</data>
</input>

Ich muß in einer Webform Felder anhand des Feldnamens und des Names vom Value vorbelegen.

Wäre klasse wenn mir da jemand weiterhelfen könnte da ich an der Sache nicht einfach nicht weiter komm.

Gruß

bhort · 9. August 2005

Spontan sehe ich zwei Lösungsmöglichkeiten.
1.) Per LotusScript in WebQueryOpen-Agent.
2.) Per JavaScript direkt im Browser.

WebQueryOpen-Agent können sich bei einer hohen Anzahl von Zugriffen zu einem Performance-Bottleneck entwickeln.

JavaScript im Browser funktioniert halt nur dann, wenn der User es aktiviert hat.

Es hängt also ein wenig von der Anwendung und der Infrastruktur ab.

Zu der 1. Lösung findest Du in der Domino Designer Hilfe unter dem Stichwort "Using XML with LotusScript". (Notes 6)
Ansonsten auf gibt es entsprechende Artikel auf den IBM DeveloperWorks Lotus-Seiten. Einfach nach XML suchen.

Die zweite Lösung ist von Domino eigentlich unabhängig. Also einfach mal nach JavaScript und XML googlen.

Codde · 9. August 2005

Danke erstmal für die Antwort, bringt mich aber nicht wirklich weiter.
Das Script wird vom WebQueryOpen aufgerufen.
Ich bin auch schon (wie in der Hilfe beschrieben) soweit gekommen, dass ich den XML-String an einen Parser übergebe, dann .Process ausführe und den Baum letzten Endes mit .Document erhalte.
Aber wie navigiere ich in diesem Baum?

bhort · 9. August 2005

Es gibt zwei Möglichkeiten XML in LotusScript zu parsen. Entweder per SAX oder per DOM.

SAX steht für "Simple API for XML" und liest den kompletten XML-Baum in einem Rutsch und erzeugt für jedes Öffnen und jedes Schließen eines Tags ein Event. SAX ist sehr schnell, aber man muss sich selber darum kümmern, wo im Baum man sich gerade befindet.

DOM (Document Object Model) ist eine allgemeine API zum durchwandern eines Documentes in Baum-Form.

Das folgende Beispiel zeigt die Feldinhalte an.

Code

Sub Initialize
  Dim strXML As String  
  Dim domParser As NotesDOMParser
  Dim nodeRoot As NotesDOMDocumentNode
  Dim node As NotesDOMNode
  Dim stream As NotesStream
  Dim nodeList As NotesDOMNodeList
  Dim DOMNamedNodeMap As NotesDOMNamedNodeMap
  Dim attribute As Notesdomattributenode
  Dim i As Integer
  Dim i1 As Integer
  Dim strAttributesLIST List As String
  Dim nodeChild As NotesDOMNode
  Dim nodeSubChild As NotesDOMNode
  Dim nodeSubSubChild As NotesDOMNode
  Dim sn As New NotesSession

  strXML = |<?xml version="1.0" encoding="UTF-8"?>| & Chr$(10)
  strXML = strXML & |<input>| & Chr$(10)
  strXML = strXML & |  <form name="Form1">| & Chr$(10)
  strXML = strXML & |    <data>| & Chr$(10)
  strXML = strXML & |      <value name="feldname 1">inhalt feld 1</value>| & Chr$(10)
  strXML = strXML & |      <value name="feldname 2">inhalt feld 2</value>| & Chr$(10)
  strXML = strXML & |    </data>| & Chr$(10)
  strXML = strXML & |  </form>| & Chr$(10)
  strXML = strXML & |  <form name="Form2">| & Chr$(10)
  strXML = strXML & |    <data>| & Chr$(10)
  strXML = strXML & |      <value name="feldname 1">inhalt feld 1</value>| & Chr$(10)
  strXML = strXML & |      <value name="feldname 2">inhalt feld 2</value>| & Chr$(10)
  strXML = strXML & |    </data>| & Chr$(10)
  strXML = strXML & |  </form>| & Chr$(10)
  strXML = strXML & |</input>| & Chr$(10)


  Set stream = sn.CreateStream
  stream.WriteText(strXML)

  Set domParser = sn.CreateDOMParser
  Call domParser.setInput(stream)
  Call domParser.Parse

    'Root-Element
  Set nodeRoot = domParser.Document

  Set nodeList = nodeRoot.GetElementsByTagName("form")

  If nodeList.NumberOfEntries <> 0 Then 
    For i = 1 To nodeList.NumberOfEntries
      Set node = nodeList.GetItem(i)

      Set DOMNamedNodeMap = node.Attributes

      If DOMNamedNodeMap.NumberOfEntries > 0 Then
        For i1 = 1 To DOMNamedNodeMap.NumberOfEntries
          Set attribute = DOMNamedNodeMap.GetItem(i1)
          strAttributesLIST(Lcase(attribute.AttributeName)) = attribute.AttributeValue        
        Next i1      
      End If 'DOMNamedNodeMap.NumberOfEntries > 0

      If Iselement(strAttributesLIST("name")) Then
        If strAttributesLIST("name") = "Form2" Then

          If node.HasChildNodes Then
            Set nodeChild = node.FirstChild
            Do Until nodeChild.IsNull

              Select Case Lcase(nodeChild.NodeName)

              Case "data":
                If nodeChild.HasChildNodes Then

                  Set nodeSubChild = nodeChild.FirstChild

                  Do Until nodeSubChild.IsNull

                    If Lcase(nodeSubChild.NodeName) = "value" Then
                      Erase strAttributesLIST

                      Set DOMNamedNodeMap = nodeSubChild.Attributes

                      If DOMNamedNodeMap.NumberOfEntries > 0 Then
                        For i1 = 1 To DOMNamedNodeMap.NumberOfEntries
                          Set attribute = DOMNamedNodeMap.GetItem(i1)
                          strAttributesLIST(Lcase(attribute.AttributeName)) = attribute.AttributeValue        
                        Next i1      
                      End If 'DOMNamedNodeMap.NumberOfEntries > 0

                      If nodeSubChild.HasChildNodes Then
                        Set nodeSubSubChild = nodeSubChild.FirstChild

                        Do Until nodeSubSubChild.IsNull 

                          If nodeSubSubChild.NodeValue <> "" Then
                            If Iselement(strAttributesLIST("name")) Then
                              Messagebox strAttributesLIST("name") & ": " & nodeSubSubChild.NodeValue
                            End If
                          End If

                          Set nodeSubSubChild = nodeSubSubChild.NextSibling
                        Loop

                      End If

                    End If ' Lcase(nodeSubChild.NodeName) = "value" 

                    Set nodeSubChild = nodeSubChild.NextSibling

                  Loop

                End If                

              End Select

              Set nodeChild = nodeChild.NextSibling
            Loop  
          End If

        End If


      End If


    Next i    
  End If
End Sub

Alles anzeigen

In einer produktiven Umgebung würde man es sicherlich anders programmieren. Aber für den ersten Eindruck sollte es genügen.

Ansonsten würde ich raten, einfach den Debugger einzuschalten und sich den Ablauf anzusehen. In der Hilfe gibt es bei den Methoden und Eigenschaften der «Class» NotesDOMNode einige Beispiele.

Codde · 11. August 2005

Ok, danke!

XML auswerten

Teilen

Benutzer online in diesem Thema