Toolbar mit @Commands Buttons exportieren

Orangie2 · 9. April 2015

Hallo,

Ich suche seit ein paar Tagen nach einer Lösung für folgendes Problem:

ich fertige im Moment Textbaustein-Buttons an (mit Hilfe von simplen @Commands).
Nun wurden mehrere Bekannte neidisch auf diese schnelle Möglichkeit seine Mails mit Standardtext zu füllen.

Diese Bekannten sind größtenteils nicht allzu technikafin und ich würde gerne eine .msi Datei oder ähnliches (zum einfachen Import) verschicken können.
Mir ist bekannt, dass diese Toolbars bei mir im Bookmark.nsf hitnerlegt sind, wie ich diese allerdings "schön" weitergeben kann, ist mir leider unbekannt.
Meine IT-Kenntnisse beschränken sich leider auf die eines neugierigen Anwenders.

Ich habe einige solcher Anfragen in anderen Foren gefunden allerdings nie mit zufriedenstellender Lösung dabei.

Vielleicht kann mir ja jemand helfen auf jedenfall schonmal vielen Dank vorweg!

grüße
Orangie2

taurec · 9. April 2015

Das ganze ist in der Bookmark.nsf als Outline hinterlegt.
Mit Script kannst du diese auch in andere Bookmarks kopieren.

Stichworte wären die Methode addEntry der NotesOutline Klasse

Orangie2 · 10. April 2015

Hat vielleicht jemand hier aus dem Forumm schon ein entsprechendes Script, was ich nur leicht anpassen muss?
Meine Programmierkenntnisse beschränken sich auf HTML und amateurhaft zusammengewerkelte @Commands.
Habe mir die entsprechenden Befehle angeschaut und verstehe leider nicht wirklich viel.

Tode · 10. April 2015

Das Problem ist: Du müsstest dem anderen Benutzer DEINE Bookmark zur Verfügung stellen, und das geht ja nicht, weil das eine Lokale Datenbank auf Deinem Client ist.
Wenn Du das schaffst (da brauchst Du einen Admin dazu) brauchst Du die Möglichkeit / die Berechtigung eine LotusScript- Aktion / einen Agenten / eine Schaltfläche zu versenden, die recht komplexen Code enthält. Hier mal ein Auszug von Code, den ich hier für genau so einem Zweck verwende... Der Code ist nicht lauffähig und tut ein wenig mehr als das, was Du brauchst... Ist nur zur Demonstration, dass das "mit ein paar Zeilen Code, die Du für Deine Zwecke anpassen kannst" nicht getan ist...

Code

'- Get Source outline
    Set olSource = g_dbCurrent.Getoutline("BEFRTools")

    '- Get the first root entry for the new outline
    Set olentry = olSource.Getfirst()
    While Not olentry Is Nothing
        strToolbarName = olentry.Label
        strEntryName = olentry.Alias
        If InStr( strEntryName , "~" ) > 0 Then
            strTargetOutlineName = StrToken( strEntryName , "~" , 1 )
        Else
            strTargetOutlineName = "UserToolbar"
        End If
        arrPlaceHolderValues(0) = strToolbarname
        arrPlaceHolderValues(1) = strTargetOutlineName

        '- Get Bookmark outline
        Set olBookmark = dbBookmark.Getoutline( strTargetOutlineName )
        blnFound = False
        blnUpdate = True
        strAction = "created"
        lintImages( "replaced" ) = 0
        lintImages( "skipped" ) = 0
        lintImages( "copied" ) = 0

        '- Find the toolbar in the target database and remove it
        Set olentryBookmark = olBookmark.Getfirst()
        While Not olentryBookmark Is Nothing And blnFound = False
            If olentryBookmark.Label = strToolbarname Then '- toolbar found
                blnFound = True
                ok = MessageboxTranslatedWithPlaceholders( TRANSLATION_TOOLBAR, "InstallToolbarQuestionReplace", MB_YESNO + Mb_iconquestion, "TitleQuestion", ArrayAdd( "<ToolbarName>" , "<OutlineName>" ), ArrayAdd( strToolbarname, strTargetOutlineName ) )
                If ok = Idyes Then
                    blnUpdate = True
                    strAction = "updated"
                    '- Now remove the old toolbar to recreate it as copy
                    '- First: Run through all childs
                    Set olentryBookmarkChild = olBookmark.Getchild( olentryBookmark )
                    While Not olentryBookmarkChild Is Nothing
                        Set olEntryBookmarkChildNext = olBookmark.Getnextsibling( olentryBookmarkChild )
                        '- And remove them
                        Call olBookmark.Removeentry( olentryBookmarkChild )
                        Set olentryBookmarkChild = olEntryBookmarkChildNext
                    Wend
                Else
                    blnUpdate = False
                End If
            End If
            If blnFound = True And blnUpdate = True Then
                '- Now remove the root entry
                Call olBookmark.Removeentry( olEntryBookmark )
                Set olEntryBookmark = Nothing
            Else
                Set olentryBookmark = olBookmark.Getnextsibling( olentryBookmark )
            End If
        Wend

        If blnUpdate = True Then
            '- Save our changes
            Call olBookmark.Save()

            '- Now recreate the toolbar from scratch
            Set olentryBookmark = olBookmark.Createentryfrom( olentry )

            '- Now cycle through all child entries
            Set olentryReferenceBookmark = olEntryBookmark
            blnAddAsChild = True
            Set olentryChild = olSource.Getchild(olentry)
            While Not olentryChild Is Nothing
                '- And copy them as a child document to the toolbar
                Set olentryBookmarkChild = olBookmark.Createentryfrom( olentryChild, olentryReferenceBookmark, True, blnAddAsChild )
                Set olentryReferenceBookmark = olentryBookmarkChild
                blnAddAsChild = False
                Set olentryChild = olSource.Getnextsibling(olentryChild)
            Wend
            Call olBookmark.Save()
            arrPlaceHolderValues(2) = lstrActions( strAction )
            strResult = strResult & nl & Replace( Translate( TRANSLATION_TOOLBAR , "InstallToolbarSuccess" ), arrPlaceHolders, arrPlaceHolderValues )
        End If
        Set olentry = olSource.Getnextsibling(olEntry)
    Wend

Alles anzeigen

Orangie2 · 10. April 2015

Vielen Vielen Dank das hat mir sehr geholfen!

Ich wünsche ein schönes Wochenende.

Teilen