Archivierung

Klingt nicht danach als ob ihr die Standardnotesarchivierung einsetzt, sondern irgendein Fremprodukt dafür.

Was für eines denn ?

[color=FF0000]Bitte aufs Themenpräfix achten[/color]

Hallo,

es handelt sich um eine eigene Erweiterung für die Überführung von Mails in unser Archiv-System.
Die zu archivierende Mail wird um eine xml-Datei mit Meta-Informationen erweitert und an eine bestimmt Adresse gesendet. Von dort holt sich das Archivsystem die Mails ab.

Die Fehlermeldung tritt nur bei einem Anwender auf. Der Fehler verweist auf die Zeile beim Versenden der Mail.

archivDoc.Send(False)

Beim Debuggen sind auch immer alle Objekte gesetzt.

Hat jemand diese Fehlermeldung schon mal gesehen?

Danke,
GerdH

Sub ArchivPostSaveExtension(Source As NotesUIDocument)

	On Error Goto Fehler

	Dim session As New NotesSession
	Dim db As NotesDatabase
	Dim doc As NotesDocument
	Dim archivdoc As NotesDocument

	Dim ArchivMailAddress As String
	Dim sSubject As String
	Dim FileName As String

	Set db = session.CurrentDatabase
	Set doc = source.Document


'Empfänger-Adresse aus Konfig-Datenbank auslesen	
	ArchivMailAddress = ...
	sSubject = "Archiv: " + doc.ArchivDocType(0)

'XML-Datei für Indizierung generieren
	FileName = MQGenerateXML(doc)	
	If FileName = "Error" Then
		Messagebox "Die Erzeugung der Archiv-Informationen ist fehlgeschlagen" & Chr$(13) & "Die Archivierung wird abgebrochen", 64, "Archivierung"
		Exit Sub
	End If

'Mail für Archivsystem erstellen	
	Set archivdoc = db.CreateDocument

	archivdoc.form 		= "Memo"
	archivdoc.SendTo 	= ArchivMailAddress
	archivdoc.Subject 	= sSubject

	Dim doc_from As NotesItem
	Dim doc_to As NotesItem
	Dim doc_cc As NotesItem		
	Dim doc_bcc As NotesItem	
	Dim doc_subject As NotesItem
	Dim body As NotesRichTextItem
	Dim rtbody As NotesRichTextItem

	Set doc_from = doc.getFirstItem("From")
	Set doc_to = doc.getFirstItem("EnterSendTo")
	Set doc_cc = doc.getFirstItem("EnterCopyTo")
	Set doc_bcc = doc.getFirstItem("EnterBlindCopyTo")
	Set doc_subject = doc.getFirstItem("Subject")

	Set rtbody = New NotesRichTextItem( archivdoc, "Body" )

'Header der ursprünglichen Mail im Body der Archiv-Mail erstellen	
	If GenerateArchivHeader(rtbody, doc_from.Text, doc_to.Text, doc_cc.Text, doc_bcc.Text, doc_subject.Text)  = False Then
		Messagebox "Die Archivierung wird abgebrochen", 64, "Archivierung"
		Exit Sub
	End If

'Original-Body an den Header anhängen	
	Set body = doc.GetFirstItem("Body")
	Call rtbody.AppendRTItem( body )
	Call rtbody.AddNewLine(2)

'XML-Datei anhängen	
	Dim XMLAttachment As NotesEmbeddedObject
	Set XMLAttachment = rtbody.EmbedObject( 1454, "", FileName )

'Mail an Archivsystem versenden	
	Call archivdoc.send(False)

	Messagebox "Die Mail wurde erfolgreich an das Archivsystem weitergeleitet!", 64, "Archivierung"

'Archiv-Zeichen entfernen
	Call doc.RemoveItem( "Archiv_flag2" )

	Call doc.Save(False, False)

Ende:	
	Exit Sub

Fehler:
	Messagebox "Fehler in Modul ArchivPostSaveExtensions!"+Chr$(13)+ Error + " in Line " + Cstr(Erl), 16, "Fehler bei Archivierung"
	Resume Ende


End Sub

Das Problem ist die Art und Weise wie ihr das macht.
So kann es nicht funktionieren, denn ihr kopiert bei AppendToRTItem maximal die ersten 32 KB des RichTextItems und damit läuft das bei jedem größeren Anhang zwangsweise schief.

Idealer ist es das gesamte Dokument zu kopieren und die überflüssigen Elemente rauszulöschen

Hallo Taurec,

danke für den Hinweis, ich werde dies bei Gelegenheit mal umstellen.

Allerdings erklärt es nicht, wieso der Fehler nur bei einer Person auftaucht. Wird die Mail an einen Kollegen weitergeleitet, so kann dieser die Mail problemlos archivieren. Die Größe der Anhänge scheint auch nicht ausschlaggebend zu sein (Es wurden schon Mails >9MB problemlos so verarbeitet).

Gibt es nähere Infos, wo und wie das rtItem von der Methode beschnitten wird? In der Notes-Hilfe fand ich keinen Hinweis dazu. Gilt dies nur für den Text, der in dem rtItem steht? Wie werden die in dem rtItem befindlichen Anhänge behandelt? ...

Gruß,
GerdH

Also in der Hilfe steht genau diese Beschneidung bei Nutzung von AppendRTItem ab 32 KB drin.

Na vermutlich wird bei diesem der Inhalt des RichTextItems diese Grenze überschreiten und bei den anderen eben nicht

Hallo Taurec,

in der Designer Hilfe 6.5.1 finde ich bei der Beschreibung der Methode keinen Hinweis auf eine Beschränkung.
Auch in 8.5 nicht: AppentRTItem
Wo finde ich denn die Beschränkungen in der Hilfe?

Die Ursache der Fehlermeldung konnten wir jetzt auf die Sicherheitseinstellungen in den Benutzervorgaben zurückführen.
Nachdem der Haken bei "Gespeicherte Kopie der gesendeten Mail verschlüsseln" entfernt wurde, hat alles wieder funktioniert.

Gruß,
GerdH

Also bei mir steht da unter den Beispieln noch folgendes:

Zitat

Hinweis The changes are not visible until the document (after the script has completed) is closed and reopened. Also note that the AppendRichTextItem method appends only the first 32K of a RichTextItem; the remainder is truncated.

Übrigens sowohl in der 6.5er,7er, 8er und 8,5er Hilfe