"remote" Replik erzeugen

wolmart · 19. Juni 2009

Hallo Zusammen,

ich habe folgendes Problem:

Wir haben einen Agenten erstellt, der Editoren ermöglicht eine Datenbank in einen konfigurierten Ordner auf den Server zu erstellen. (Die Herren kommen gerne Freitags kurz von deren Feierabend und benötigen die DB dann Montags morgens um 8.00 Uhr )

Klappt auch alles soweit. Das Setup-Dokument ruft den Backend-Agenten auf welcher mit (onBehalfof) Adminrechten läuft, erzeugt die Datebank mit dem Template.

Das eigentliche Problem besteht darin, dass ich eine Replic auf den Failoverserver erzeuge, welche dann einen Fehler rückmeldet, weil die Datenbank erstmal nur als Stub generiert wurde. Diese soll aber wohl sofort geöffnet werden, was den Fehler verursacht.

Code

On Error Goto errhandle
        If Not serverReplic = "" Then
                 Call newDb.CreateReplica(serverReplic,pfad+dbname)
 	End If

Ich könnte den Fehler ignorieren, möchte das aber nicht, falls mal ein "echter" Fehler auftritt.

Hat jemand eine Idee wie das vernünftig handlebar ist ?

Danke.

Wolfgang

taurec · 19. Juni 2009

Dann musst du vor dem Öffnen eben noch eine Replizierung durchführen (Methode Replicate)

wolmart · 19. Juni 2009

Hallo Taurec,

hatte ich versucht, das Problem liegt darin, dass das öffnen der Datenbank in dem Moment passiert, wenn die Datenbank angelegt wird.

Code

Call newDb.CreateReplica(serverReplic,pfad+dbname)
Call newDb.replicate(serverReplic)

funktioniert nicht, da der Agent in der ersten Zeile schon aussteigt:

2009-06-19 15:36:18 Agent printing: CRITICAL ERROR: INITIALIZE aufgerufen von INITIALIZE: Fehler (4060) Zeile: 127 - User CN=[Name des OnBehalfOf]/OU=dor/OU=de/O=[FIRMA] cannot open database dor-lddev-02/[Firma]!!clients\aktionen\09-0007 projectname.nsf

Ich komme um das "öffnen" nicht herum, obwohl ich das weder benötige noch will....

taurec · 19. Juni 2009

Wer öffnet die Datenbank denn, denn beim Aufruf von CreateReplica wird sie nicht geöffnet sondern nur ein entsprechendes ungeöffnetes Objekt zurückgeliefert

wolmart · 19. Juni 2009

Das weiß ich halt nicht, für mich sieht das leider so aus, als würde der Befehl "CreateReplica" das machen, da man dort auch die Replikdatenbank zurückgeben könnte.
(set replicdb = neueDB.CreateReplica(server,pfad))

Als Frontent-Agent in Clientcontext hat das mit den entsprechenden Rechten auch problemlos funktioniert. Da der Kontext aber Adminrechte benötigt, und die o.g. Herren diese Rechte nicht haben dürfen, habe ich daraus einen Agenten gestrickt der mit "runOnServer" angestoßen wird und die Rechte von Admin bekommt.

Danke

Wolfgang

(Wünsche dann ein schönes Wochenende und würde mich dann am Montag wieder melden)

taurec · 19. Juni 2009

Dann poste doch mal das ganze Script und vor allem was in Zeile 127 steht

wolmart · 22. Juni 2009

Hallo Taurec,

Ich hoffe Du hattest ein gutes Wochenende

Der Code:
=======
DAs QuerySave-Object im Konfigurationsdokument:

Code

Sub Querysave(Source As Notesuidocument, Continue As Variant) 	Dim db As NotesDatabase 	Dim doc As NotesDocument 	Set doc =  source.document 	Set db = doc.ParentDatabase  	' Eingabe in das Backend schieben 	Call source.refresh 	Call doc.Save(True,False)  	' Agenten ausführen 	Dim agent As NotesAgent 	Set agent = db.GetAgent("newDB") 	Dim nid As String 	nid = doc.NoteID 	Call agent.RunOnServer(nid)  	' doc "refreshen" 	Delete doc	 	Set doc = db.GetDocumentByID(nid) 	 	' Fehlermeldungen 	If (doc.getitemvalue("status")(0) <> "") Then 		Messagebox doc.getitemvalue("status")(0) , , "ERROR" 	Else 		Messagebox "database generated\n on " + server + dbpath , , "SUCCESS"	 	End If  	' doc schließen 	continue= False 	Call source.Close 	Call doc.Remove(True) End Sub

Der eigentliche Agent:
==============

Code

Declaration:
Const strTemplate = "sp_projekttemplate.ntf"


Initialize:
'/**
' * Agent creates a database and a replication in the failoverserver<br>
' * The filename is generated in three parts, year + number + name<br>
' * <p></p>
' * @version 1.0
' * @author Wolfgang Martens
' * @param session:NotesSession actual Notessession
' * @param [GLOBAL] pdoc - the document that "called" the agent, containing the filename and returning the status
' * @return Boolean - true, if the agent has sucessfully run (status via the configurationdocument)
' */
Sub Initialize
	On Error Goto errhandle
	Dim session As New NotesSession
	Dim strMessage As String

	Dim server As String
	Dim serverReplic As String
	Dim pfad As String
	Dim dbname As String
	Dim titel As String

	Dim accessManager As New StringList
	Dim accessDesigner As New StringList
	Dim accessEditor As New StringList
	Dim accessAuthor As New StringList
	Dim accessReader As New StringList
	Dim accessDepositor As New StringList
	Dim accessNone As New StringList

	'Profiledoc "setup" (server, path, foserver)
	Dim prfdoc As NotesDocument
	Set prfdoc = session.CurrentDatabase.GetProfileDocument("setup")

	'Configurationdoc: name settings
	Dim agent As NotesAgent
	Set agent = session.CurrentAgent
	Dim pdoc As NotesDocument
	Set pdoc = session.CurrentDatabase.GetDocumentByID(agent.ParameterDocID)

	On Error Goto errorProfile
	server = prfdoc.GetItemValue("projectsDBServer")(0)
	serverReplic=prfdoc.GetItemValue("projectsDBServerFO")(0)
	pfad = prfdoc.GetItemValue("projectsDBPath")(0)

	If server = "" Then
		server = session.CurrentDatabase.Server
	End If

	' setting ACL
	'Call accessManager.add("&aAdmins_DSA",True) -> ACL Template
	'Call accessManager.add("&aDevelopers",True) -> ACL Template
	'Call accessManager.add("LocalDomainServers",True) -> ACL Template
	'Call accessNone.add("-Default-",True) -> ACL Template


	On Error Goto errorServer	
	'Enables Working at design :-)
	If Lcase(server) = "[testserver]" Then
		Call accessManager.add("Admin",True)	
		Call accessManager.add("Developer",True)	
		Call accessDesigner.add("Developer_apprentice",True)	
	End If

	titel = pdoc.GetItemValue("sName")(0)
	dbname = titel + ".nsf"

	' generates the database
	On Error Goto errorPfad
	Dim template As New NotesDatabase 	(server, strTemplate )
	Dim newDB As New NotesDatabase( server,pfad+dbname )
	If newDB.IsOpen Then
		Print ( "The database " + dbname + " already exists." )
		Call pdoc.ReplaceItemValue("status",  "The database " + dbname + " already exists." )
		Call pdoc.Save(True,False)
	Else
		Print ( "Creating the database and replic for " + dbname)
		If Not template.IsOpen Then
			Goto errorTemplate
		End If
		On Error Goto errorNewDB
		Set newdb = template.CreateFromTemplate( server, pfad+dbname, True )
		newdb.Title = titel
			' set acl
		If accessManager.count > 0 Then
			Call dbaccess(newDB, accessManager.toVariant(), ACLLEVEL_MANAGER)			
		End If
		If accessDesigner.count > 0 Then
			Call dbaccess(newDB, accessDesigner.toVariant(), ACLLEVEL_DESIGNER)			
		End If
		If accessEditor.count > 0 Then
			Call dbaccess(newDB, accessEditor.toVariant(), ACLLEVEL_EDITOR)		
		End If
		If accessAuthor.count > 0 Then
			Call dbaccess(newDB, accessAuthor.toVariant(), ACLLEVEL_AUTHOR)		
		End If
		If accessReader.count > 0 Then
			Call dbaccess(newDB, accessReader.toVariant(), ACLLEVEL_READER)			
		End If
		If accessDepositor.count > 0 Then
			Call dbaccess(newDB, accessDepositor.toVariant(), ACLLEVEL_DEPOSITOR)			
		End If
		If accessNone.count > 0 Then
			Call dbaccess(newDB, accessNone.toVariant(), ACLLEVEL_NOACCESS)		
		End If			

		' ACL Anpassen

		Dim acl As NotesACL
		Dim aclEntry As NotesACLEntry
		Set acl = newdb.ACL
		Print "Adding roles to "  + session.userName

		Set aclEntry = acl.GetEntry(server)			
		Forall r In acl.Roles
			Call aclEntry.EnableRole(r)
		End Forall

		Set aclEntry = acl.GetEntry(session.UserName)
		Call aclEntry.Remove
		Call acl.Save

'		On Error Goto errorServerFO
		On Error Goto errhandle		
		If Not serverReplic = "" Then
[b]			Call newDb.CreateReplica(serverReplic,pfad+dbname)
[/b]		End If
	End If

	Exit Sub

errhandle:
	strMessage = Lsi_info(2) & " aufgerufen von " & Lsi_info(12) & ": Fehler (" & Cstr(Err) & ") Zeile: " & Cstr(Erl) & " - " & Error$ & Chr(10)
	strMessage = strMessage & "Fehler " & Cstr(Err) &  ": " & Error(Cstr(Err)) & Chr(10)
	Print "CRITICAL ERROR: " + strMessage
	Call pdoc.ReplaceItemValue("status",  "CRITICAL ERROR: " + strMessage)
	Call pdoc.Save(True,False)
	Exit Sub

errorProfile:
	strMessage = "Profiledocument was not found. Please contact you administrator." & Chr(10)
	strMessage = strMessage & "Fehler " & Cstr(Err) &  ": " & Error(Cstr(Err)) & Chr(10)
	Print "ERROR: " + strMessage
	Call pdoc.ReplaceItemValue("status",  "ERROR: " + strMessage)
	Call pdoc.Save(True,False)
	Exit Sub

errorNewDB:
	strMessage = "Generated Database was not found. Please contact you administrator." & Chr(10)
	strMessage = strMessage & "Fehler " & Cstr(Err) &  ": " & Error(Cstr(Err)) & Chr(10)
	Print "ERROR: " + strMessage
	Call pdoc.ReplaceItemValue("status",  "ERROR: " + strMessage)
	Call pdoc.Save(True,False)
	Exit Sub

errorTemplate:
	strMessage = "Template to generate database not found. Please contact you administrator. (Templatename: " + strTemplate +")" & Chr(10)
	strMessage = strMessage & "Fehler " & Cstr(Err) &  ": " & Error(Cstr(Err)) & Chr(10)
	Print "ERROR: " + strMessage
	Call pdoc.ReplaceItemValue("status",  "ERROR: " + strMessage)
	Call pdoc.Save(True,False)
	Exit Sub

errorServer:
	strMessage = "Server for generating database not found. Please check setup (Project Databases - Server)." & Chr(10)
	strMessage = strMessage & "Fehler " & Cstr(Err) &  ": " & Error(Cstr(Err)) & Chr(10)
	Print "ERROR: " + strMessage
	Call pdoc.ReplaceItemValue("status",  "ERROR: " + strMessage)
	Call pdoc.Save(True,False)
	Exit Sub

errorServerFO:
	strMessage = "Server for generating failover database not found. Please check setup (Project Databases - FailoverServer)." & Chr(10)
	strMessage = strMessage & "Fehler " & Cstr(Err) &  ": " & Error(Cstr(Err)) & Chr(10)
	strMessage = strMessage & serverReplic & " " & pfad+dbname & Chr(10)
	Print "ERROR: " + strMessage
	Call pdoc.ReplaceItemValue("status",  "ERROR: " + strMessage)
	Call pdoc.Save(True,False)
	Exit Sub

errorPfad:
	strMessage = "Path for generating database not found. Please check setup (Project Databases - Database Path)." & Chr(10)
	strMessage = strMessage & "Fehler " & Cstr(Err) &  ": " & Error(Cstr(Err)) & Chr(10)
	Print "ERROR: " + strMessage
	Call pdoc.ReplaceItemValue("status",  "ERROR: " + strMessage)
	Call pdoc.Save(True,False)
	Exit Sub

End Sub

Alles anzeigen

Zeile 127 ist fett hinterlegt.
Auch über das Wochenende habe ich da leider keine andere Lösung gefunden / Idee gehabt, da man aus Gründen der Rechte die Erstellung der Replikation ebenfalls im Backend laufen lassen muss.

Danke.

Vielleicht hast Du ja einen Idee...

Wolfgang

wolmart · 2. Juli 2009

Hat jemand eine Idee....

Danke.

hchudek · 3. August 2009

Hallo,

hast du mal versucht, den Return-Wert in ein neues Datenbankobjekt zurückzuschreiben, wie es die Designerhilfe vorsieht, vielleicht funktioniert die call-Routine hier nicht bzw. verursacht dann das Öffnen der Datenbank :

Dim replica As NotesDatabase
Set db = session.CurrentDatabase
Set replica = db.CreateReplica( "Jakarta", "sales.nsf" )

statt
call db.CreateReplica( "Jakarta", "sales.nsf" )

Das replica-Objekt sollte dann auch eigentlich nicht geöffnet sein,

ist vielleicht ein Versuch wert.

mfg

Holger

wolmart · 19. August 2009

Hallo Zusammen,

die Ursache des Problems lag in einem anderen Bereich, den Rechten...

session.userName bekommt in diesem Agenten nicht den Wert dessen unter den der Agent läuft ("Run on behalf of") sondern unter dem Namen des Servers.

Das bedeutet, dass der Server aus der ACL gelöscht wird.
Dann wird der DB Stub auf dem Backupserver erzeugt. Der Server kann aber nicht mehr darauf zugreifen. Daher kommt die Fehlermeldung. (Seltsamerweise wird die Gruppe "LocalDomainServers", wo beide Server eingetragen sind nicht berücksichtigt, was ich zumindest erwartet hätte.)

Ich habe den Code wie folgt geändert:

Code

Set aclEntry = acl.GetEntry("[Name des Admins]")Call aclEntry.Remove Call acl.Save

...

Code

If Not serverReplic = "" Then 
Call newDb.CreateReplica(serverReplic,pfad+dbname) 
Call newDb.Replicate(serverReplic) 
End If

Danke für Eure Hilfe

Wolfgang

"remote" Replik erzeugen

Teilen

Benutzer online in diesem Thema