Import von Feiertagen

wenn du die id hast dann such doch mal in der db nach diesem dokument...einfach im adminclient reiter dateien unter werkzeuge...

Die Suche nach der verursachenden ID ist im mehrfachen Sinn nutzlos, laß es besser.

Das Problem rührt aus der Art & Weise, wie die Feiertage in der Mail-DB als solche vermerkt werden: Es werden beim Import nicht nur simpel die Kalendereinträge erzeugt sondern es wird zusätzlich ein "Holidayprofile" geschrieben. Dieses erhält die UNID's aller Feiertagsdokumente. Nur so kann ein erneuter Import ohne Duplikate oder eine Feiertagsänderung den konkreten Terminen zugeordnet werden.

Läuft der Import nicht so heißt das also simpel: beim letzten Import wurde ein Profildokument erzeugt dessen IDs nicht mehr zu den aktuellen Feiertagen passen.

LÖSUNG:
a) alle bereits importierten Feiertage löschen (über die Ansicht "Meetings" sinnvollerweise)
b) Feiertagsprofildokument löschen
c) neuen Import starten

Bsp.-Script zum Löschen des Profildokuments:

Dim s As New Notessession	
Dim p As NotesDocument
Set p=s.CurrentDatabase.GetProfileDocument("holidayprofile")
Call p.remove(True)

Ok, habs grad selber mal geprüft...seit meinem letzten echten Feiertagsproblem gabs ein paar Änderungen am Mailtemplate. Feiertage und Kalendereinträge, insbesondere Wiederholungen, lassen sich jetzt dank neuer Prüfmechanismen im Datenbankscript nicht mehr versehentlich löschen.

Dummerweise damit aber auch nicht mehr ohne weiteres absichtlich...!

Eh ich jetzt lang und breit erklär wie man die Einträge trotzdem auf "normalem" Weg löscht hab ich einfach mein Beispielscript um das Löschen der Feiertage erweitert.

Script natürlich auf eigene Gefahr und ohne Gewähr, kurz getestet mit 6.5.3. Bitte als neuen Agent in der betroffenen DB anlegen (ist am einfachsten).

Sub Initialize
%REM
Agent 'DeleteHolidays', Version 1.0 für Notes 6.5.x
Author: Carsten Hädicke 
Auslöser: Ereignis
Laufzeit: Auswahl im Menü 'Aktionen'
Laufziel: Keines
%END REM	
	Dim s As New NotesSession
	Dim db As NotesDatabase
	Dim col As NotesDocumentCollection
	Dim doc As NotesDocument
	Dim deldoc As NotesDocument
	Dim dt As NotesDateTime

	On Error Goto ErrHandler
	Set db = s.CurrentDatabase

	Print "Feiertage werden gesucht..."
	Set col = db.Search(|$CSFlags="hc"|, Nothing, 0)

	Print "Feiertage werden gelöscht..."
	Set doc = col.GetFirstDocument()
	While Not(doc Is Nothing)
		Set deldoc = doc
		Set doc = col.GetNextDocument(doc)
		Print "Feiertage werden gelöscht..." & deldoc.subject(0)
		Call deldoc.Remove(True)
	Wend

	Print "Feiertagsprofil wird gelöscht..."
	Set deldoc=db.GetProfileDocument("holidayprofile")
	Call deldoc.Remove(True)

	Msgbox "Feiertagsprofil wurde bereinigt und alle importierten Feiertage wurden gelöscht. " &_
	"Sie können Feiertage nun neu importieren."
	Exit Sub

ErrHandler:
	Messagebox "Error" & Str(Err) & ": " & Error$
	Exit Sub
End Sub

Hallo Carsten,

Du bist ein Gott! Vielen Dank für diese sehr schöne Lösung. So was in der Richtung wollte ich auch mal schreiben...
Wir hatten bisher auch immer wieder Probleme mit den Feiertagen. Darüber hinaus haben wir auch die MA-Geburtstage fort hinterlegt. Und da kam es öfter zu Problemen.

Ein Kleinigkeit habe ich jedoch noch geändert. Bei uns hatte das mit dem $CSFlags="hc"

Print "Feiertage werden gesucht..."Set col = db.Search(|$CSFlags="hc"|, Nothing, 0)

nicht so gut geklappt. Ich habe dann das Kriterium in Type="Holiday" geändert.

Print "Feiertage werden gesucht..."
Set col = db.Search(|Type="Holiday"|, Nothing, 0)

Dann habe ich es mit ´ner Schaltfläche noch in ´ne Mail geklatscht und schon ist das wirklich wunderbar. - Vielen Dank noch mal.

Es klappt übrigens auch unter R5.

Grüße

Christian

Hallo Dirk,

ooops, da hast Du mir doch grade ein schlechtes Gewissen gemacht. :-?
Bei genauerem Überlegen ist mir eingefallen, dass die Personalabteilung aber monatlich an den schwarzen Brettern die Geburtstagslisten aushängt. Und bisher hat sich keiner drüber beschwert. - Zeugen Jehovas darf man natürlich nicht reinnehmen. Sonst gibts Ärger..

Danke jedoch für den Hinweis. Ich klär das mal bei uns im Haus ab.

Grüße

Christian

Zitat

wuhogo schrieb:
Hallo Carsten,

Du bist ein Gott!

Danke für die Blumen Vielleicht trägt unser Admin den neuen Titel gleich mal ein?

Zitat

Ein Kleinigkeit habe ich jedoch noch geändert. Bei uns hatte das mit dem $CSFlags="hc" nicht so gut geklappt. Ich habe dann das Kriterium in Type="Holiday" geändert.

Jupp, das Kriterium kann bei unterschiedlichen Notesversionen durchaus Anpassungen erfordern. Insofern gut zu wissen daß es so auch für dich und sogar mit R5 klappt! Danke für die Info an die Allgemeinheit hier.

Anmerkung zu den Geburtstagen: die meisten haben kein Problem damit solange keine Jahreszahlen Rückschluß auf das Alter zulassen. Das Tagesdatum an sich ist eigentlich unproblematisch.

Vielen Dank Carsten und wuhogo,

auch ich habe dieses Script erfolgreich genutzt!!!

Vielen Dank an die Authoren. Habe das Script auch mit Erfolg genutzt. Funktioniert auch unter 7.0!